File Coverage

blib/lib/FFI/Platypus/Record/StringArray.pm

Criterion	Covered	Total	%
statement	34	34	100.0
branch	2	2	100.0
condition	1	3	33.3
subroutine	10	10	100.0
pod	4	4	100.0
total	51	53	96.2

package FFI::Platypus::Record::StringArray;

use strict;
use warnings;
use 5.008001;
use FFI::Platypus::Memory qw( strdup calloc free );
use constant _ptr_size => FFI::Platypus->new->sizeof('opaque');

# ABSTRACT: Array of strings for your FFI record
our $VERSION = '0.01'; # VERSION


my $ffi;

sub new
{
  my $class = shift;

  $ffi ||= FFI::Platypus->new( lib => [undef] );

  my $size       = @_;
  my $array      = [map { defined $_ ? strdup($_) : undef } @_, undef];
  my $opaque     = calloc($size, _ptr_size);

  $ffi->function(
    memcpy => [ 'opaque', "opaque[$size]", 'size_t' ] => 'opaque',
  )->call($opaque, $array, $size * _ptr_size);

  my $self = bless {
    array => $array,
    opaque => $opaque,
  }, $class;
}


sub opaque
{
  my($self) = @_;
  $self->{opaque};
}


sub size
{
  my($self) = @_;
  scalar @{ $self->{array} } - 1;
}


sub element
{
  my($self, $index) = @_;
  $ffi->cast( 'opaque' => 'string', $self->{array}->[$index] );
}

sub DESTROY
{
  my($self) = @_;
  free($_) for grep { defined $_ } @{ $self->{array} };
  free($self->{opaque});
}

1;

__END__