File Coverage

blib/lib/FFI/C/Stat.pm

Criterion	Covered	Total	%
statement	23	24	95.8
branch	5	6	83.3
condition	1	3	33.3
subroutine	7	7	100.0
pod	1	1	100.0
total	37	41	90.2

package FFI::C::Stat;

use strict;
use warnings;
use 5.008004;
use Ref::Util qw( is_ref is_globref is_blessed_ref );
use Carp ();
use FFI::Platypus 1.00;

# ABSTRACT: Object-oriented FFI interface to native stat and lstat
our $VERSION = '0.01'; # VERSION


my $ffi = FFI::Platypus->new( api => 1 );
$ffi->bundle;      # for accessors / constructor / destructor

$ffi->type('object(FFI::C::Stat)', 'stat');
if($^O eq 'MSWin32')
{
  $ffi->type('uint' => $_) for qw( uid_t gid_t nlink_t blksize_t blkcnt_t );
}

$ffi->mangler(sub { "stat__$_[0]" });

$ffi->attach( '_stat'  => ['string'] => 'opaque' );
$ffi->attach( '_fstat' => ['int',  ] => 'opaque' );
$ffi->attach( '_lstat' => ['string'] => 'opaque' );


sub new
{
  my($class, $file, %options) = @_;

  my $ptr;
  if(is_globref $file)
  { $ptr = _fstat(fileno($file)) }
  elsif(!is_ref($file) && defined $file)
  { $ptr = $options{symlink} ? _lstat($file) : _stat($file) }
  else
  { Carp::croak("Tried to stat something whch is neither a glob reference nor a plain string") }

  bless \$ptr, $class;
}


$ffi->attach( clone => ['opaque'] => 'opaque' => sub {
  my($xsub, $class, $other) = @_;

  my $ptr;
  if(is_blessed_ref $other)
  {
    if($other->isa('FFI::C::Stat'))
    {
      $ptr = $xsub->($$other);
    }
    else
    {
      Carp::croak("Not a FFI::C::Struct instance");
    }
  }
  elsif(!is_ref $other)
  {
    $ptr = $xsub->($other);
  }
  else
  {
    Carp::croak("Not an FFI::C::Struct structure or opaque pointer");
  }

  bless \$ptr, $class;
});

$ffi->attach( DESTROY => ['stat'] );


$ffi->attach( dev     => ['stat'] => 'dev_t'     );
$ffi->attach( ino     => ['stat'] => 'ino_t'     );
$ffi->attach( mode    => ['stat'] => 'mode_t'    );
$ffi->attach( nlink   => ['stat'] => 'nlink_t'   );
$ffi->attach( uid     => ['stat'] => 'uid_t'     );
$ffi->attach( gid     => ['stat'] => 'gid_t'     );
$ffi->attach( rdev    => ['stat'] => 'dev_t'     );
$ffi->attach( size    => ['stat'] => 'off_t'     );
$ffi->attach( atime   => ['stat'] => 'time_t'    );
$ffi->attach( mtime   => ['stat'] => 'time_t'    );
$ffi->attach( ctime   => ['stat'] => 'time_t'    );

if($^O ne 'MSWin32')
{
  $ffi->attach( blksize => ['stat'] => 'blksize_t' );
  $ffi->attach( blocks  => ['stat'] => 'blkcnt_t'  );
}
else
{
  *blksize = sub { '' };
  *blocks  = sub { '' };
}

1;

__END__