File Coverage

blib/lib/Exporter/Declare/Magic.pm

Criterion	Covered	Total	%
statement	50	66	75.7
branch	5	16	31.2
condition	2	12	16.6
subroutine	15	18	83.3
pod	7	7	100.0
total	79	119	66.3

package Exporter::Declare::Magic;
use strict;
use warnings;

our $VERSION = '0.107';

use Devel::Declare::Parser;
use aliased 'Exporter::Declare::Magic::Sub';
use aliased 'Exporter::Declare::Export::Generator';
use Carp qw/croak/;
our @CARP_NOT = qw/
    Exporter::Declare
    Exporter::Declare::Specs
    Exporter::Declare::Meta
    Exporter::Declare::Magic
    /;

BEGIN {
    die "Devel::Declare::Parser version >= 0.017 is required for -magic\n"
        unless $Devel::Declare::Parser::VERSION gt '0.016';
}

use Devel::Declare::Parser::Sublike;

use base 'Exporter::Declare';
use Exporter::Declare
    'default_exports',
    'reexport',
    export             => {-as => 'ed_export'},
    gen_export         => {-as => 'ed_gen_export'},
    default_export     => {-as => 'ed_default_export'},
    gen_default_export => {-as => 'ed_gen_default_export'};

default_exports qw/
    parsed_exports
    parsed_default_exports
    /;

parsed_default_exports( sublike => qw/parser/ );

parsed_default_exports(
    export => qw/
        export
        gen_export
        default_export
        gen_default_export
        /
);

Exporter::Declare::Meta->add_hash_metric('parsers');

reexport('Exporter::Declare');

sub export {
    my $class = Exporter::Declare::_find_export_class( \@_ );
    _export( $class, undef, @_ );
}

sub gen_export {
    my $class = Exporter::Declare::_find_export_class( \@_ );
    _export( $class, Generator(), @_ );
}

sub default_export {
    my $class = Exporter::Declare::_find_export_class( \@_ );
    my $meta  = $class->export_meta;
    $meta->export_tags_push( 'default', _export( $class, undef, @_ ) );
}

sub gen_default_export {
    my $class = Exporter::Declare::_find_export_class( \@_ );
    my $meta  = $class->export_meta;
    $meta->export_tags_push( 'default', _export( $class, Generator(), @_ ) );
}

sub _export {
    my %params = Exporter::Declare::_parse_export_params(@_);
    my ($parser) = @{$params{args}};
    if ($parser) {
        my $ec = $params{export_class};
        if ( $ec && $ec eq Generator ) {
            $params{extra_exporter_props} = {parser => $parser, type => Sub};
        }
        else {
            $params{export_class} = Sub;
            $params{extra_exporter_props} = {parser => $parser};
        }
    }
    Exporter::Declare::_add_export(%params);
}

sub parser {
    my $class = Exporter::Declare::_find_export_class( \@_ );
    my $name  = shift;
    my $code  = pop;
    croak "You must provide a name to parser()"
        if !$name || ref $name;
    croak "Too many parameters passed to parser()"
        if @_ && defined $_[0];
    $code ||= $class->can($name);
    croak "Could not find code for parser '$name'"
        unless $code;

    $class->export_meta->parsers_add( $name, $code );
}

sub parsed_exports {
    my $class = Exporter::Declare::_find_export_class( \@_ );
    my ( $parser, @items ) = @_;
    croak "no parser specified" unless $parser;
    _export( $class, Sub(), $_, $parser ) for @items;
}

sub parsed_default_exports {
    my $class = Exporter::Declare::_find_export_class( \@_ );
    my ( $parser, @names ) = @_;
    croak "no parser specified" unless $parser;

    for my $name (@names) {
        _export( $class, Sub(), $name, $parser );
        $class->export_meta->export_tags_push( 'default', $name );
    }
}

1;

__END__