File Coverage

blib/lib/Evo/Di.pm

Criterion	Covered	Total	%
statement	81	81	100.0
branch	38	50	76.0
condition	3	3	100.0
subroutine	11	11	100.0
pod	3	3	100.0
total	136	148	91.8

package Evo::Di;
use Evo -Class, '-Class::Attrs ECA_REQUIRED';
use Evo 'Module::Load load; Module::Loaded is_loaded; Carp croak';

has di_stash => sub { {} };

our @CARP_NOT = ('Evo::Class::Attrs');

my sub _croak_cirk (@path) { croak "Circular dependencies detected: " . join(' -> ', @path); }
my sub _croak ($cur_key, $req_key) {
  croak qq#Can't load dependency "$cur_key" for class "$req_key"#;
}

# TODO: copypase, optimaze
sub mortal ($self, $class, %args) {
  load $class;
  my @stack = _di_list_pending($self, $class);
  my %in_stack;
  while (@stack) {
    my $cur = pop @stack;
    my @pending = _di_list_pending($self, $cur);
    if (!@pending) {
      $self->{di_stash}{$cur} = $cur->new(_di_args($self, $cur));
      next;
    }
    _croak_cirk(@stack, $cur) if $in_stack{$cur}++;
    push @stack, $cur, @pending;
  }
  $class->new(%args, _di_args($self, $class));
}

sub single ($self, $key) {
  return $self->{di_stash}{$key} if exists $self->{di_stash}{$key};
  $self->{di_stash}{$key} = $self->mortal($key);
}

sub provide ($self, %args) {
  foreach my $k (keys %args) {
    croak qq#Already has key "$k"# if exists $self->{di_stash}{$k};
    $self->{di_stash}{$k} = $args{$k};
  }
}

sub _di_list_pending ($self, $req_key) : Private {
  return unless $req_key->can('META');
  my @results;
  foreach my $slot ($req_key->META->attrs->slots) {
    next if !(my $k = $slot->{inject});

    next if exists $self->{di_stash}{$k};
    my $loaded = is_loaded($k) || eval { load($k); 1 };
    do { push @results, $k; next; } if $loaded;
    _croak($k, $req_key) if $slot->{type} == ECA_REQUIRED;
  }

  @results;
}

# only existing key/values to ->new, skip missing
sub _di_args ($self, $key) : Private {
  return unless $key->can('META');
  my @opts;

  foreach my $slot ($key->META->attrs->slots) {
    next unless my $k = $slot->{inject};
    push @opts, $slot->{name}, $self->{di_stash}{$k} if exists $self->{di_stash}{$k};
  }
  (@opts, $self->{di_stash}{"$key\@defaults"} ? $self->{di_stash}{"$key\@defaults"}->%* : ());
}


1;

# ABSTRACT: Dependency injection

__END__