File Coverage

blib/lib/Error/Tiny.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	13	14	92.8
condition	2	3	66.6
subroutine	10	10	100.0
pod	0	3	0.0
total	66	71	92.9

package Error::Tiny;

use strict;
use warnings;

use vars qw(@ISA @EXPORT @EXPORT_OK);

our $VERSION = '0.03';

BEGIN {
    require Exporter;
    @ISA = qw(Exporter);
}

@EXPORT = @EXPORT_OK = qw(try then catch);

require Carp;
$Carp::Internal{+__PACKAGE__}++;

require Scalar::Util;

use Error::Tiny::Exception;
use Error::Tiny::Catch;
use Error::Tiny::Then;

sub try(&;@) {
    my ($try, @handlers) = @_;

    my $wantarray = wantarray;

    my @ret;
    eval { @ret = $wantarray ? $try->() : scalar $try->(); 1 } || do {
        my $e      = $@;
        my $orig_e = $e;

        if (!Scalar::Util::blessed($e)) {
            $orig_e =~ s{ at ([\S]+) line (\d+)\.\s*$}{}ms;
            $e = Error::Tiny::Exception->new(
                message => $orig_e,
                file    => $1,
                line    => $2
            );
        }

        for my $handler (@handlers) {
            if ($handler && $handler->isa('Error::Tiny::Catch')) {
                if ($e->isa($handler->class)) {
                    return $handler->handler->($e);
                }
            }
        }

        Carp::croak($orig_e);
    };

    return $wantarray ? @ret : $ret[0];
}

sub catch(&;@) {
    my ($class, $handler) =
      @_ == 2 ? ($_[0], $_[1]->handler) : ('Error::Tiny::Exception', $_[0]);

    Error::Tiny::Catch->new(handler => $handler, class => $class);
}

sub then(&;@) {
    my ($handler, $subhandler) = @_;

    (Error::Tiny::Then->new(handler => $handler), $subhandler);
}

1;
__END__