File Coverage

blib/lib/Email/MIME/Attachment/Stripper.pm

Criterion	Covered	Total	%
statement	46	48	95.8
branch	15	20	75.0
condition	13	19	68.4
subroutine	9	9	100.0
pod	3	3	100.0
total	86	99	86.8

use strict;
use warnings;
package Email::MIME::Attachment::Stripper;
{
  $Email::MIME::Attachment::Stripper::VERSION = '1.317';
}
# ABSTRACT: strip the attachments from an email

use Email::MIME 1.861; # new(\$str)
use Email::MIME::ContentType 1.016; # type/subtype
use Carp;


sub new {
  my ($class, $email, %attr) = @_;
  $email = Email::MIME->new($email) if (ref($email) || 'SCALAR') eq 'SCALAR';

  croak "Need a message" unless ref($email) || do {
    require Email::Abstract;
    $email = Email::Abstract->cast($email, 'Email::MIME');
  };

  bless { message => $email, attr => \%attr }, $class;
}


sub message {
  my ($self) = @_;
  $self->_detach_all unless exists $self->{attach};
  return $self->{message};
}


sub attachments {
  my $self = shift;
  $self->_detach_all unless exists $self->{attach};
  return $self->{attach} ? @{ $self->{attach} } : ();
}

sub _detach_all {
  my ($self, $part) = @_;
  $part ||= $self->{message};
  return if $part->parts == 1;

  my @attach = ();
  my @keep   = ();
  foreach ( $part->parts ) {
    my $ct = $_->content_type                  || 'text/plain';
    my $dp = $_->header('Content-Disposition') || 'inline';

    push(@keep, $_) and next
      if $ct =~ m[text/plain]i && $dp =~ /inline/i;
    push @attach, $_;
    if ($_->parts > 1) {
      my @kept=$self->_detach_all($_);
      push(@keep,@kept) if @kept;
    }
  }

  $part->parts_set(\@keep);
  push @{$self->{attach}}, map {;
    my $content_type = parse_content_type($_->content_type);
    {
      content_type => join('/', @{$content_type}{qw[type subtype]}),
      payload      => $_->body,
      filename     => $self->{attr}->{force_filename}
                    ? $_->filename(1)
                    : ($_->filename || ''),
    }
  } @attach;

  return @keep;
}


1;

__END__