File Coverage

blib/lib/Disassemble/X86/FormatText.pm

Criterion	Covered	Total	%
statement	38	48	79.1
branch	22	30	73.3
condition	4	7	57.1
subroutine	5	5	100.0
pod	1	2	50.0
total	70	92	76.0

package Disassemble::X86::FormatText;

use 5.006;
use strict;
use warnings;

my %size_tag = (
    8   => "byte",
    16  => "word",
    32  => "dword",
    64  => "qword",
    80  => "tbyte",
    128 => "dqword",
);

my %far_size_tag = (
    32  => "far",
    48  => "far32",
);

sub format_instr {
  my ($self, $tree) = @_;
  my $op  = $tree->{op};
  my $arg = $tree->{arg};

  if ($tree->{prefix}) {
    $arg = $self->format_instr($arg->[0]);
    $arg .= " ." unless $arg =~ / /;
    return "$op $arg";
  }
  elsif ($op eq "push") {
    $arg = $arg->[0];
    if ($arg->{op} eq "lit") {
      my $size = $arg->{size};
      $size = $size_tag{$size} if $size;
      $size ||= "";
      $arg = format_arg($arg);
      return "push $size($arg)";
    }
    else {
      $arg = format_arg($arg);
      return "push $arg";
    }
  }
  elsif ($arg && @$arg) {
    $arg = join ",", map(format_arg($_), @$arg);
    return "$op $arg";
  }
  else {
    return $op;
  }
} # format_instr

sub format_arg {
  my ($tree) = @_;
  my $op  = $tree->{op};
  my $arg = $tree->{arg};

  if ($op eq "reg") {
    return $arg->[0];
  }
  elsif ($op eq "lit") {
    return sprintf "0x%x", $arg->[0];
  }
  elsif ($op eq "farlit") {
    return sprintf "0x%x:0x%x", @$arg;
  }
  elsif ($op eq "mem") {
    my $size = $tree->{size};
    my $tag = !$size ? ""
        : ($tree->{far} ? $far_size_tag{$size} : $size_tag{$size}) || "";
    $arg = format_arg($arg->[0]);
    return "$tag\[$arg]";
  }
  elsif ($op eq "seg") {
    my $seg = format_arg($arg->[0]);
    my $off = format_arg($arg->[1]);
    return "$seg:$off";
  }
  elsif ($op eq "+") {
    return join "+", map(format_arg($_), @$arg);
  }
  elsif ($op eq "*") {
    my $lhs = format_arg($arg->[0]);
    my $rhs = $arg->[1];
    $rhs = ($rhs->{op} eq "lit") ? $rhs->{arg}[0] : format_arg($rhs);
    return "$lhs*$rhs";
  }
  return $op;
} # format_arg

1 # end FormatText.pm
__END__