File Coverage

blib/lib/Device/RFXCOM/Decoder/Digimax.pm

Criterion	Covered	Total	%
statement	40	40	100.0
branch	8	8	100.0
condition			n/a
subroutine	9	9	100.0
pod	1	1	100.0
total	58	58	100.0

use strict;
use warnings;
package Device::RFXCOM::Decoder::Digimax;
$Device::RFXCOM::Decoder::Digimax::VERSION = '1.163170';
# ABSTRACT: Device::RFXCOM::Decoder::Digimax decode Digimax RF messages


use 5.006;
use constant DEBUG => $ENV{DEVICE_RFXCOM_DECODER_DIGIMAX_DEBUG};
use Carp qw/croak/;
use base 'Device::RFXCOM::Decoder';
use Device::RFXCOM::Response::Thermostat;
use Device::RFXCOM::Decoder qw/hi_nibble lo_nibble nibble_sum/;


sub decode {
  my ($self, $parent, $message, $bytes, $bits, $result) = @_;
  return unless ($bits == 44);
  my $p =
    hi_nibble($bytes->[0]) + lo_nibble($bytes->[0]) +
      hi_nibble($bytes->[1]) + lo_nibble($bytes->[1]) +
        hi_nibble($bytes->[2]) + lo_nibble($bytes->[2]);
  $p &= 0xf;
  return unless ($p == 0xf);

  $p =
    hi_nibble($bytes->[3]) + lo_nibble($bytes->[3]) +
      hi_nibble($bytes->[4]) + lo_nibble($bytes->[4]) +
        hi_nibble($bytes->[5]);
  $p &= 0xf;
  return unless ($p == 0xf);

  my $state =
    [
     'undef', 'demand', 'satisfied', 'init'
    ]->[hi_nibble($bytes->[2])&0x3];

  my $temp = $bytes->[3];
  my $set = $bytes->[4]&0x3f;
  my $mode = $bytes->[4]&0x40 ? 'cool' : 'heat';
  my $device = sprintf 'digimax.%02x%02x', $bytes->[0], $bytes->[1];
  printf STDERR "Thermostat: $device $state $temp $set $mode\n" if DEBUG;
  push @{$result->{messages}},
    Device::RFXCOM::Response::Thermostat->new(device => $device,
                                              temp => $temp,
                                              set => $set,
                                              mode => $mode,
                                              state => $state);
  return 1;
}

1;

__END__