File Coverage

blib/lib/Device/RFXCOM/Decoder/HomeEasy.pm

Criterion	Covered	Total	%
statement	53	53	100.0
branch	14	14	100.0
condition	3	3	100.0
subroutine	9	9	100.0
pod	2	2	100.0
total	81	81	100.0

use strict;
use warnings;
package Device::RFXCOM::Decoder::HomeEasy;
$Device::RFXCOM::Decoder::HomeEasy::VERSION = '1.142010';
# ABSTRACT: Device::RFXCOM::Decoder::HomeEasy decode HomeEasy RF messages


use 5.006;
use constant DEBUG => $ENV{DEVICE_RFXCOM_DECODER_HOMEEASY_DEBUG};
use Carp qw/croak/;
use base 'Device::RFXCOM::Decoder';
use Device::RFXCOM::Response::HomeEasy;


sub decode {
  my ($self, $parent, $message, $bytes, $bits, $result) = @_;

  $bits == 34 or $bits == 38 or return;

  # HomeEasy devices seem to send duplicates with different byte[4] high nibble
  my @b = @{$bytes};
  my $b4 = $b[4];
  $b[4] &= 0xf;
  if ($b[4] != $b4) {
    $result->{key} = $bits.'!'.(pack "C*", @b);
    my $entry = $parent->_cache_get($result);
    if ($entry) {
      $result->{messages} = $entry->{result}->{messages};
      $result->{duplicate} = $parent->_cache_is_duplicate($entry);
      return 1;
    }
    $b[4] = $b4;
  }

  my $res = from_rf($bits, $bytes);

  printf "homeeasy c=%s u=%s a=%x\n",
    $res->{command}, $res->{unit}, $res->{address} if DEBUG;
  my %body = (
              address => (sprintf "%#x",$res->{address}),
              unit => $res->{unit},
              command => $res->{command},
             );

  $body{level} = $res->{level} if ($res->{command} eq 'preset');

  push @{$result->{messages}}, Device::RFXCOM::Response::HomeEasy->new(%body);
  return 1;
}


sub from_rf {
  my $length = shift;
  my $bytes = shift;
  my %p = ();
  $p{address} = ($bytes->[0] << 18) + ($bytes->[1] << 10) +
    ($bytes->[2] << 2) + ($bytes->[3] >> 6);
  my $command = ($bytes->[3] >> 4) & 0x3;
  $p{unit} = ($command & 0x2) ? 'group' : ($bytes->[3] & 0xf);
  if ($length == 38) {
    $p{command} =  'preset';
    $p{level} = $bytes->[4] >> 4;
  } else {
    $p{command} = ($command & 0x1) ? 'on' : 'off';
  }
  return \%p;
}

1;

__END__