File Coverage

blib/lib/Devel/Platform/Info/Solaris.pm

Criterion	Covered	Total	%
statement	9	30	30.0
branch	0	8	0.0
condition			n/a
subroutine	3	5	60.0
pod	2	2	100.0
total	14	45	31.1

package Devel::Platform::Info::Solaris;

use strict;
use warnings;

use vars qw($VERSION);
$VERSION = '1.00';

#----------------------------------------------------------------------------

my %commands = (
    '_uname1'   => 'uname -a',
    '_showrev'  => 'showrev -a | grep -v "^Patch"',
    '_release'  => 'cat /etc/release',
    '_isainfo'  => '/usr/bin/isainfo -kv',
    'kname'     => 'uname -s',
    'kvers'     => 'uname -r',
    'archname'  => 'uname -m',
);

#----------------------------------------------------------------------------

sub new {
    my ($class) = @_;
    my $self = {};
    bless $self, $class;

    return $self;
}

sub get_info {
    my $self  = shift;

    for my $cmd (keys %commands) {
        $self->{cmds}{$cmd} = `$commands{$cmd} 2>/dev/null`;
        $self->{cmds}{$cmd} =~ s/\s+$//s;
        $self->{info}{$cmd} = $self->{cmds}{$cmd}   if($cmd !~ /^_/);
    }

    $self->{info}{osflag}   = $^O;
    $self->{info}{kernel}   = lc($self->{info}{kname}) . '-' . $self->{info}{kvers};
    $self->{info}{is32bit}  = $self->{cmds}{_isainfo} !~ /64-bit/s ? 1 : 0;
    $self->{info}{is64bit}  = $self->{cmds}{_isainfo} =~ /64-bit/s ? 1 : 0;

    ($self->{info}{osname}) = $self->{cmds}{_release} =~ /((?:Open)?Solaris|SunOS|OpenIndiana)/is;
    $self->{info}{oslabel}  = $self->{info}{osname};
    $self->{info}{osvers}   = $self->{info}{kvers};

    # Solaris versions are based on SunOS, but just slightly different!
    if($self->{info}{osname} =~ /Solaris/) {
        $self->{info}{osvers} =~ s/^5\.([0123456]\b)/2.$1/;
        $self->{info}{osvers} =~ s/^5\.(\d+)/$1/;
    }

    # Question: Anyone know how to get the real version number for OpenSolaris?
    # i.e. "2008.05" or "2009.06"

    $self->{info}{source}{$commands{$_}} = $self->{cmds}{$_}    for(keys %commands);
    return $self->{info};
}

#----------------------------------------------------------------------------

1;

__END__