File Coverage

blib/lib/DateTimeX/Factory.pm

Criterion	Covered	Total	%
statement	42	43	97.6
branch	2	4	50.0
condition	4	8	50.0
subroutine	19	20	95.0
pod	13	13	100.0
total	80	88	90.9

package DateTimeX::Factory;
use 5.010_001;
use strict;
use warnings;

our $VERSION = '1.00';

use Class::Accessor::Lite (
    new => 0,
    rw  => [qw/default_options/],
);

use DateTime;
use DateTime::Format::Strptime;

sub new {
    my ($class, %default_options) = @_;
    bless {default_options => \%default_options}, $class;
}

sub create            {shift->_call_factory_method('new' => @_)}
sub now               {shift->_call_factory_method('now' => @_)}
sub from_epoch        {shift->_call_factory_method('from_epoch' => @_)}
sub today             {shift->_call_factory_method('today' => @_)}
sub last_day_of_month {shift->_call_factory_method('last_day_of_month' => @_)}
sub from_day_of_year  {shift->_call_factory_method('from_day_of_year' => @_)}

sub _call_factory_method {
    my ($self, $method, @params) = @_;
    DateTime->$method(%{$self->default_options}, @params);
}

sub strptime {
    my ($self, $string, $pattern) = @_;
    return DateTime::Format::Strptime->new(
        pattern => $pattern,
        %{$self->default_options},
    )->parse_datetime($string);
}

sub from_mysql_datetime {
    my ($self, $string) = @_;

    return if !defined $string ||  $string eq '0000-00-00 00:00:00';

    return $self->strptime($string, '%Y-%m-%d %H:%M:%S');
}

sub from_ymd {
    my ($self, $string, $delimiter) = @_;

    $delimiter //= '-';
    return $self->strptime($string, join($delimiter, '%Y','%m','%d'));
}

sub from_mysql_date {
    my ($self, $string) = @_;

    return if !defined $string ||  $string eq '0000-00-00';
    return $self->from_ymd($string);
}

sub yesterday {shift->today(@_)->subtract(days => 1)}
sub tommorow  {shift->today(@_)->add(days => 1)}

1;
__END__