File Coverage

blib/lib/DateTime/Language.pm

Criterion	Covered	Total	%
statement	4	6	66.6
branch			n/a
condition			n/a
subroutine	2	2	100.0
pod			n/a
total	6	8	75.0

package DateTime::Language;

use strict;

use Class::Factory::Util;
use Params::Validate qw( validate SCALAR );
use vars qw ( %ISOMap );

# my %ISOMap;
foreach my $set ( [ 'aa', 'aar'                 => 'Afar' ],
                  [ 'am', 'amh'                 => 'Amharic' ],
                  [ 'cz', 'ces', 'cze'          => 'Czech' ],
                  [ 'de', 'deu', 'ger'          => 'German' ],
                  [ 'de-at', 'deu-at', 'ger-at' => 'Austrian' ],
                  [ 'dk', 'dan'                 => 'Danish' ],
                  [ 'en', 'eng'                 => 'English' ],
                  [ 'es', 'esl', 'spa'          => 'Spanish' ],
                  [ 'fr', 'fra', 'fre'          => 'French' ],
                  [ 'x-drs', 'sil-drs'          => 'Gedeo' ],
                  [ 'it', 'ita'                 => 'Italian' ],
                  [ 'nl', 'dut', 'nla'          => 'Dutch' ],
                  [ 'no', 'nor'                 => 'Norwegian' ],
                  [ 'om', 'orm'                 => 'Oromo' ],
                  # not quite right, but better than failing
                  [ 'pt', 'por'                 => 'Brazilian' ],
                  [ 'pt-br', 'por-br'           => 'Brazilian' ],
                  [ 'sid'                       => 'Sidama' ],
                  [ 'so', 'som'                 => 'Somali' ],
                  [ 'sv', 'sve', 'swe'          => 'Swedish' ],
                  [ 'ti-et', 'tig-et'           => 'TigrinyaEthiopian' ],
                  [ 'ti-er', 'tig-er'           => 'TigrinyaEritrean' ],
             )
{
    my $module = pop @$set;
    @ISOMap{ @$set } = ($module) x @$set;
}

# print "ISOMap: $ISOMap{sid}\n";

sub new
{
    my $class = shift;
    my %p = validate( @_,
                      { language => { type => SCALAR } },
                    );

    my $real_class = $class->load( $p{language} );

    my $obj = bless {}, $real_class;

    $obj->_init;

    return $obj;
}

sub languages { $_[0]->subclasses }
sub iso_codes { keys %ISOMap }

sub class_base
{
	"DateTime::Language";
}


sub load
{
    my $class = shift;
    my $lang = shift;

    my $real_lang;
    if ( $lang =~ /^((?:x-)?\w\w\w?)(?:-\w\w\w?)?$/ )
    {
        $real_lang =
            ( exists $ISOMap{$lang} ?
              $ISOMap{$lang} :
              $1 ?
              $ISOMap{$1} :
              undef
            );

        die "Unsupported or invalid ISO language code, $lang"
            unless defined $real_lang;
    }
    else
    {
        $real_lang = $lang;
    }

    my $real_class = $class->class_base."::$real_lang";
    eval "use $real_class";
    die $@ if $@;

    # print "XLoading $real_class\n";
    return $real_class;
}

sub _init
{
    my $self = shift;
    my $class = ref $self;

    foreach my $key ( qw( day_names day_abbreviations month_names
                          month_abbreviations am_pm ordinal_suffixes
                          month_numbers day_numbers
                        )
                    )
    {
        my $var_name = join '', map { ucfirst } split /_/, $key;
        $var_name = 'AMPM' if $var_name eq 'AmPm';

        no strict 'refs';
        if ( $key =~ /numbers$/ )
        {
            $self->{$key} = \%{"$class\::$var_name"};
        }
        else
        {
            $self->{$key} = \@{"$class\::$var_name"};
        }
    }
}

sub month_names { $_[0]->{month_names} }

sub month_name  { $_[0]->{month_names}[ $_[1]->month_0 ] }

sub day_names { $_[0]->{day_names} }

sub day_name  { $_[0]->{day_names}[ $_[1]->day_of_week_0 ] }

sub month_abbreviations { $_[0]->{month_abbreviations} }

sub month_abbreviation  { $_[0]->{month_abbreviations}[ $_[1]->month_0 ] }

sub day_abbreviations { $_[0]->{day_abbreviations} }

sub day_abbreviation  { $_[0]->{day_abbreviations}[ $_[1]->day_of_week_0 ] }

sub am_pm_list { $_[0]->{am_pm} }

sub am_pm { $_[0]->{am_pm}[ $_[1]->hour < 12 ? 0 : 1 ] }

#sub preferred_datetime_format { '%m/%d/%y %H:%M:%S' }
#sub preferred_date_format { '%m/%d/%y' }
#sub preferred_time_format { '%H:%M:%S' }

1;

__END__