File Coverage

blib/lib/DataStructure/LinkedList.pm

Criterion	Covered	Total	%
statement	77	82	93.9
branch	3	4	75.0
condition			n/a
subroutine	16	17	94.1
pod	6	9	66.6
total	102	112	91.0

# A linked list data-structure.

package DataStructure::LinkedList;

use strict;
use warnings;
use utf8;
use feature ':5.24';
use feature 'signatures';
no warnings 'experimental::signatures';

use DataStructure::LinkedList::Node;

=pod

=head1 NAME

DataStructure::LinkedList

=head1 SYNOPSIS

A linked list data-structure, written in pure Perl.

See also L for a double-linked list version that
offers a richer interface.

=head1 DESCRIPTION

=head2 CONSTRUCTOR

Cnew()>

Creates an empty list.

=cut

sub new ($class) {
  return bless { size => 0, first => undef}, $class;
}

=pod

=head2 METHODS

All the functions below are class methods that should be called on a
B object. Unless documented, they run in constant
time.

=head3 I

Returns the first L of the list, or B if
the list is empty.

=cut

sub first ($self) {
  return $self->{first};
}

=pod

=head3 I

Adds a new node at the beginning of the list with the given value. Returns the
newly added node.

For conveniance, I can be used as a synonym of I.

=cut

sub unshift ($self, $value) {
  my $new_node = DataStructure::LinkedList::Node->new($self, $self->{first}, $value);
  $self->{first} = $new_node;
  $self->{size}++;
  return $new_node;
}

sub push ($self, $value) {
  return $self->unshift($value);
}

=pod

=head3 I

Removes the first node of the list and returns its value. Returns B if
the list is empty. Note that the method can also return B if the first
node’s value is B

For conveniance, I can be used as a synonym of I.

=cut

sub shift ($self) {
  return unless defined $self->{first};
  my $old_first = $self->first();
  $self->{first} = $old_first->next();
  return $old_first->_delete_first();
}

sub pop ($self) {
  $self->shift();
}

=pod

=head3 I

Returns the number of nodes in the list.

=cut

sub size ($self) {
  return $self->{size};
}

=pod

=head3 I

Returns whether the list is empty.

=cut

sub empty ($self) {
  return $self->size() == 0;
}

=pod

=head3 I

Returns all the values of the list, as a normal Perl list. This runs in linear
time with the size of the list.

=cut

sub values ($self) {
  return $self->size() unless wantarray;
  my @ret = (0) x $self->size();
  my $i = 0;
  my $cur = $self->first();
  while (defined $cur) {
    $ret[$i++] = $cur->value();
    $cur = $cur->next();
  }
  return @ret;
}

sub DESTROY ($self) {
  my $next = $self->{first};
  while (defined $next) {
    my $cur = $next;
    $next = $cur->{next};
    undef %{$cur};
  }
  return;
}

=pod

=head1 AUTHOR

Mathias Kende

=head1 LICENCE

Copyright 2021 Mathias Kende

This program is distributed under the MIT (X11) License:
L

Permission is hereby granted, free of charge, to any person
obtaining a copy of this software and associated documentation
files (the "Software"), to deal in the Software without
restriction, including without limitation the rights to use,
copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the
Software is furnished to do so, subject to the following
conditions:

The above copyright notice and this permission notice shall be
included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
OTHER DEALINGS IN THE SOFTWARE.

=head1 SEE ALSO

L

=cut

1;