File Coverage

blib/lib/Data/iRealPro/Output.pm

Criterion	Covered	Total	%
statement	18	48	37.5
branch	0	16	0.0
condition	0	14	0.0
subroutine	6	8	75.0
pod	0	2	0.0
total	24	88	27.2

#! perl

# Data::iRealPro::Output -- pass data to backends

# Author          : Johan Vromans
# Created On      : Tue Sep  6 16:09:10 2016
# Last Modified By: Johan Vromans
# Last Modified On: Mon Jan  7 09:30:08 2019
# Update Count    : 81
# Status          : Unknown, Use with caution!

################ Common stuff ################

use strict;
use warnings;
use Carp;
use utf8;

package Data::iRealPro::Output;

use Data::iRealPro::Input;
use Encode qw ( decode_utf8 );

sub new {
    my ( $pkg, $options ) = @_;

    my $self = bless( { variant => "irealpro" }, $pkg );
    my $opts;

    $opts->{output} = $options->{output} || "";
    $opts->{transpose} = $options->{transpose} // 0;
    if ( $options->{generate} ) {
	$self->{_backend} = "Data::iRealPro::Output::" . ucfirst($options->{generate});
	eval "require $self->{_backend}";
	die($@) if $@;
	$opts->{output} ||= "-";
    }

    elsif ( $options->{list}
	 || $opts->{output} =~ /\.txt$/i ) {
	require Data::iRealPro::Output::Text;
	$self->{_backend} = Data::iRealPro::Output::Text::;
	$opts->{output} ||= "-";
    }
    elsif ( $opts->{output} =~ /\.jso?n$/i ) {
	require Data::iRealPro::Output::JSON;
	$self->{_backend} = Data::iRealPro::Output::JSON::;
    }
    elsif ( $opts->{output} =~ /\.mma$/i ) {
	require Data::iRealPro::Output::MMA;
	$self->{_backend} = Data::iRealPro::Output::MMA::;
    }
    elsif ( $options->{split}
	    || $opts->{output} =~ /\.html$/i ) {
	require Data::iRealPro::Output::HTML;
	$self->{_backend} = Data::iRealPro::Output::HTML::;
    }
    elsif ( !$self->{_backend} ) {
	require Data::iRealPro::Output::Imager;
	$self->{_backend} = Data::iRealPro::Output::Imager::;
    }

    for ( @{ $self->{_backend}->options } ) {
	$opts->{$_} = $options->{$_} if exists $options->{$_};
    }

    $self->{options} = $opts;
    return $self;
}

sub processfiles {
    my ( $self, @files ) = @_;
    my $opts = $self->{options};

    my $all = Data::iRealPro::Input->new($opts)->parsefiles(@files);
    $self->{_backend}->new($opts)->process( $all, $opts );
}

1;