File Coverage

blib/lib/Data/Unixish/split.pm

Criterion	Covered	Total	%
statement	30	33	90.9
branch	3	10	30.0
condition	2	4	50.0
subroutine	8	8	100.0
pod	1	1	100.0
total	44	56	78.5

package Data::Unixish::split;

our $DATE = '2019-10-26'; # DATE
our $DIST = 'Data-Unixish'; # DIST
our $VERSION = '1.572'; # VERSION

use 5.010001;
use strict;
use syntax 'each_on_array'; # to support perl < 5.12
use warnings;
#use Log::Any '$log';

use Data::Unixish::Util qw(%common_args);

our %SPEC;

sub _pattern_to_re {
    my $args = shift;

    my $re;
    my $pattern = $args->{pattern}; defined $pattern or die "Please specify pattern";
    if ($args->{fixed_string}) {
        $re = $args->{ignore_case} ? qr/\Q$pattern/i : qr/\Q$pattern/;
    } else {
        eval { $re = $args->{ignore_case} ? qr/$pattern/i : qr/$pattern/ };
        die "Invalid pattern: $@" if $@;
    }

    $re;
}

$SPEC{split} = {
    v => 1.1,
    summary => 'Split string into array',
    description => <<'_',

_
    args => {
        %common_args,
        pattern => {
            summary => 'Pattern or string',
            schema  => 'str*',
            req     => 1,
            pos     => 0,
        },
        fixed_string => {
            summary => 'Interpret pattern as fixed string instead of regular expression',
            schema  => 'true*',
            cmdline_aliases => {F=>{}},
        },
        ignore_case => {
            summary => 'Whether to ignore case',
            schema  => 'bool*',
            cmdline_aliases => {i=>{}},
        },
        limit => {
            schema  => 'uint*',
            default => 0,
            pos     => 1,
        },
    },
    tags => [qw/text itemfunc/],
};
sub split {
    my %args = @_;
    my ($in, $out) = ($args{in}, $args{out});

    # we don't call _split_item() to optimize
    my $re = _pattern_to_re(\%args);
    while (my ($index, $item) = each @$in) {
        push @$out, [CORE::split($re, $item, $args{limit}//0)];
    }

    [200, "OK"];
}

sub _split_item {
    my ($item, $args) = @_;

    my $re = _pattern_to_re($args);
    [CORE::split($re, $item, $args->{limit}//0)];
}

1;
# ABSTRACT: Split string into array

__END__