File Coverage

blib/lib/Data/ShortNameProvider/Style/Basic.pm

Criterion	Covered	Total	%
statement	26	26	100.0
branch	2	2	100.0
condition			n/a
subroutine	10	10	100.0
pod	3	3	100.0
total	41	41	100.0

package Data::ShortNameProvider::Style::Basic;
$Data::ShortNameProvider::Style::Basic::VERSION = '1.001';
use POSIX qw( strftime );
use Sub::Quote qw( quote_sub );
use Time::Local qw( timegm );

use Moo;
use namespace::clean;

with 'Data::ShortNameProvider::Role::Style';

has version => (
    is      => 'ro',
    default => '1',
    isa     => quote_sub( << 'ISA' ),
    my ($v) = @_;
    die "'$v' is not a integer" if $v !~ /^(?:0|[1-9][0-9]*)$/;
ISA
);

has prefix => (
    is      => 'ro',
    default => 'dsnp',
);

# derived attributes

has timestamp => (
    is       => 'lazy',
    init_arg => undef,
    builder  => sub { strftime '%y%m%d', gmtime shift->timestamp_epoch; },
);

has parsing_regexp => (
    is       => 'lazy',
    init_arg => undef,
    builder  => sub {
        my ($self) = @_;
        my $re = quotemeta( $self->prefix )    # prefix
          . '(0|[1-9][0-9]*)_'                                       # version
          . '([0-9][0-9])(0[1-9]|1[012])(0[1-9]|[12][0-9]|3[01])__'  # timestamp
          . '(.*)';                                                  # name
          return qr/^$re$/;
    },
);

sub generate_name {
    my ( $self, $name ) = @_;
    return
        $self->prefix
      . $self->version . '_'
      . $self->timestamp . '__'
      . $name;
}

sub parse_generated_name {
    my ( $self, $short_name ) = @_;
    return undef if $short_name !~ $self->parsing_regexp;
    return {
        prefix          => $self->prefix,
        version         => $1,
        timestamp       => "$2$3$4",
        timestamp_epoch => timegm( 0, 0, 0, $4, $3 - 1, $2 ),
        name            => $5,
    };
}

sub is_generated_name {
    my ( $self, $short_name ) = @_;
    return scalar $short_name =~ $self->parsing_regexp;
}

1;

__END__