File Coverage

blib/lib/Data/Sah/FormatJS.pm

Criterion	Covered	Total	%
statement	20	44	45.4
branch	0	8	0.0
condition			n/a
subroutine	7	9	77.7
pod	1	1	100.0
total	28	62	45.1

package Data::Sah::FormatJS;

our $DATE = '2016-06-13'; # DATE
our $VERSION = '0.001'; # VERSION

use 5.010001;
use strict 'subs', 'vars';
use warnings;
use Log::Any::IfLOG '$log';

use Data::Sah::FormatCommon;
use IPC::System::Options;
use Nodejs::Util qw(get_nodejs_path);

our %SPEC;

our $Log_Formatter_Code = $ENV{LOG_SAH_FORMATTER_CODE} // 0;

$SPEC{gen_formatter} = {
    v => 1.1,
    summary => 'Generate formatter code',
    args => {
        %Data::Sah::FormatCommon::gen_formatter_args,
    },
    result_naked => 1,
};
sub gen_formatter {
    my %args = @_;

    my $format   = $args{format};
    my $pkg = "Data::Sah::Format::js\::$format";
    (my $pkg_pm = "$pkg.pm") =~ s!::!/!g;

    require $pkg_pm;

    my $fmt = &{"$pkg\::format"}(
        data_term => 'data',
        (args => $args{formatter_args}) x !!defined($args{formatter_args}),
    );

    my $code = join(
        "",
        "function (data) {\n",
        "    return ($fmt->{expr});\n",
        "}",
    );

    if ($Log_Formatter_Code) {
        $log->tracef("Formatter code (gen args: %s): %s", \%args, $code);
    }

    return $code if $args{source};

    state $nodejs_path = get_nodejs_path();
    die "Can't find node.js in PATH" unless $nodejs_path;

    sub {
        require File::Temp;
        require JSON::MaybeXS;
        #require String::ShellQuote;

        my $data = shift;

        state $json = JSON::MaybeXS->new->allow_nonref;

        # code to be sent to nodejs
        my $src = "var formatter = $code;\n\n".
            "console.log(JSON.stringify(formatter(".
                $json->encode($data).")))";

        my ($jsh, $jsfn) = File::Temp::tempfile();
        print $jsh $src;
        close($jsh) or die "Can't write JS code to file $jsfn: $!";

        my $out = IPC::System::Options::readpipe($nodejs_path, $jsfn);
        $json->decode($out);
    };
}

1;
# ABSTRACT: Generate formatter code

__END__