File Coverage

blib/lib/Data/Random/NL.pm

Criterion	Covered	Total	%
statement	67	69	97.1
branch	13	18	72.2
condition	2	3	66.6
subroutine	9	9	100.0
pod	3	3	100.0
total	94	102	92.1

package Data::Random::NL;
use warnings;
use strict;

# ABSTRACT: Tools for generating random Dutch numbers
our $VERSION = '1.4';

use Exporter qw(import);
use Carp qw(croak);

our @EXPORT_OK = (
    qw(
        generate_bsn
        generate_rsin
        generate_kvk
    ),
);

our %EXPORT_TAGS = (
    all => \@EXPORT_OK,
);

sub generate_bsn {
    my $begin = shift;
    my @bsn;

    eval { _starts_with(\@bsn, $begin) };
    croak "$@" if $@;

    while(@bsn < 9) {
        push(@bsn, int(rand(10)));
    }

    # A BSN cannot start with a 00
    while ($bsn[0] == 0 && $bsn[1] == 0) {
        $bsn[1] = int(rand(10));
    }

    @bsn = reverse(@bsn);

    my $sum = 0;
    foreach my $i (reverse(1..8)) {
        $sum += (($i + 1) * $bsn[$i]);
    }

    my $last_number = $sum % 11;
    # if the last number is 10, we have an invalid number
    return generate_bsn($begin) if $last_number > 9;

    @bsn = reverse(@bsn);

    $bsn[-1] = $last_number;
    return join("", @bsn);
}

sub generate_kvk {
    my $begin = shift;
    my @kvk;

    push(@kvk, 0); # first number is always a 0

    eval { _starts_with(\@kvk, $begin) };
    croak "$@" if $@;

    while(@kvk < 9) {
        push(@kvk, int(rand(10)));
    }

    @kvk = _get_last_number(@kvk);
    if (@kvk) {
        shift @kvk;
        return join("", @kvk);
    }
    return generate_kvk($begin);
}

sub generate_rsin {
    my $begin = shift;
    my @rsin;

    eval { _starts_with(\@rsin, $begin) };
    croak "$@" if $@;

    while(@rsin < 9) {
        push(@rsin, int(rand(10)));
    }

    @rsin = _get_last_number(@rsin);
    return join("", @rsin) if @rsin;
    return generate_rsin($begin);
}

sub _get_last_number {
    my @set = @_;

    @set = reverse(@set);

    my $sum = 0;
    foreach my $i (reverse(1..8)) {
        $sum += (($i + 1) * $set[$i]);
    }

    my $left = $sum % 11;
    my $last_number = abs($left - 11);

    # if the last number is 10, we have an invalid number
    return if $last_number > 9;

    $set[0] = $last_number;
    return reverse(@set);
}

sub _starts_with {
    my ($ref, $begin) = @_;

    if (defined $begin) {
        if ($begin !~ /^[0-9]$/) {
            die("You did not provide a number", $/);
        }
        push(@$ref, $begin);
        return 1;
    }
}

1;

__END__