File Coverage

blib/lib/Data/Dumper/AutoEncode.pm

Criterion	Covered	Total	%
statement	87	97	89.6
branch	26	36	72.2
condition	14	25	56.0
subroutine	18	18	100.0
pod	2	2	100.0
total	147	178	82.5

package Data::Dumper::AutoEncode;
use strict;
use warnings;
use Carp ();
use Encode ();
use Scalar::Util qw(blessed refaddr);
use B;
use Data::Dumper; # Dumper

our $VERSION = '1.00';

our $ENCODING = '';
our $CHECK_ALREADY_ENCODED = 0;
our $DO_NOT_PROCESS_NUMERIC_VALUE = 1;
our $FLAG_STR = '';

our $BEFORE_HOOK;
our $AFTER_HOOK;

sub import {
    my $class = shift;
    my %args = map { $_ => 1 } @_;

    if (delete $args{'-dumper'}) {
        no strict 'refs'; ## no critic
        *{__PACKAGE__."::Dumper"} = *{__PACKAGE__."::eDumper"};
    }

    my $export_all = !!(scalar(keys %args) == 0);

    my $pkg = caller;

    for my $f (qw/ Dumper eDumper /) {
        if ( $export_all || (exists $args{$f} && $args{$f}) ) {
            no strict 'refs'; ## no critic
            *{"${pkg}::${f}"} = \&{$f};
        }
    }
}

sub _dump {
    my $d = Data::Dumper->new(\@_);
    return $d->Dump;
}

sub eDumper {
    my @args;
    for my $arg (@_) {
        push @args, encode($ENCODING || 'utf8', $arg);
    }
    _dump(@args);
}

sub encode {
    my ($encoding, $stuff, $check) = @_;
    $encoding = Encode::find_encoding($encoding)
        || Carp::croak("unknown encoding '$encoding'");
    $check ||= 0;
    _apply(sub { $encoding->encode($_[0], $check) }, {}, $stuff);
}

# copied from Data::Recursive::Encode
sub _apply {
    my $code = shift;
    my $seen = shift;

    my @retval;
    for my $arg (@_) {
        if(my $ref = ref $arg){
            my $refaddr = refaddr($arg);
            my $proto;

            if(defined($proto = $seen->{$refaddr})){
                 # noop
            }
            elsif($ref eq 'ARRAY'){
                $proto = $seen->{$refaddr} = [];
                @{$proto} = _apply($code, $seen, @{$arg});
            }
            elsif($ref eq 'HASH'){
                $proto = $seen->{$refaddr} = {};
                %{$proto} = _apply($code, $seen, %{$arg});
            }
            elsif($ref eq 'REF' or $ref eq 'SCALAR'){
                $proto = $seen->{$refaddr} = \do{ my $scalar };
                ${$proto} = _apply($code, $seen, ${$arg});
            }
            else{ # CODE, GLOB, IO, LVALUE etc.
                $proto = $seen->{$refaddr} = $arg;
            }

            push @retval, $proto;
        }
        else{
            if (_can_exec($arg)) {
                push @retval, $FLAG_STR ? $FLAG_STR . _exec($code, $arg) : _exec($code, $arg);
            }
            else {
                push @retval, $arg;
            }
        }
    }

    return wantarray ? @retval : $retval[0];
}

sub _exec {
    my ($code, $arg) = @_;

    if (ref $BEFORE_HOOK eq 'CODE') {
        $arg = $BEFORE_HOOK->($arg);
    }

    my $result = $code->($arg);

    if (ref $AFTER_HOOK eq 'CODE') {
        return $AFTER_HOOK->($result);
    }

    return $result;
}

# copied from Data::Recursive::Encode
sub _is_number {
    my $value = shift;
    return 0 unless defined $value;

    my $b_obj = B::svref_2object(\$value);
    my $flags = $b_obj->FLAGS;
    return $flags & ( B::SVp_IOK | B::SVp_NOK ) && !( $flags & B::SVp_POK ) ? 1 : 0;
}

sub _can_exec {
    my ($arg) = @_;

    return unless defined($arg);
    return if $DO_NOT_PROCESS_NUMERIC_VALUE && _is_number($arg);
    return 1 if Encode::is_utf8($arg);
    return 1 if !$CHECK_ALREADY_ENCODED && !Encode::is_utf8($arg);

    return;
}

1;

__END__