File Coverage

blib/lib/Dancer2/Template/Haml.pm

Criterion	Covered	Total	%
statement	47	47	100.0
branch	7	8	87.5
condition			n/a
subroutine	14	14	100.0
pod	0	4	0.0
total	68	73	93.1

package Dancer2::Template::Haml;
use 5.008005;
use strict;
use warnings FATAL => 'all';
use utf8;

use Moo;

use Dancer2::Core::Types 'InstanceOf';
use Dancer2::FileUtils 'path';

use Carp qw/croak/;

use Text::Haml;

our $VERSION = 0.04; # VERSION
# ABSTRACT: Text::Haml template engine wrapper for Dancer2

with 'Dancer2::Core::Role::Template';

has '+default_tmpl_ext' => ( default => sub { 'haml' }          );
has '+engine'           => ( isa     => InstanceOf['Text::Haml']);

sub view_pathname {
  my ($self, $view) = @_;

  $view = $self->_template_name($view);

  return (ref $self->config->{path} eq 'HASH')  # virtual path
            ? $view
            : path($self->views, $view);

}

sub layout_pathname {
  my ($self, $layout) = @_;

  $layout = $self->_template_name($layout);

  return (ref $self->config->{path} eq 'HASH')  # virtual path
            ? path('layouts', $layout)
            : path($self->views, 'layouts', $layout);
}

sub render_layout {
    my ($self, $layout, $tokens, $content) = @_;

    $layout = $self->layout_pathname($layout);

    $self->engine->escape_html(0);

    # FIXME: not sure if I can "just call render"
    $self->render( $layout, { %$tokens, content => $content } );
}

sub _build_engine {
    my $self = shift;

    my %haml_args = %{ $self->config };

    #$haml_args{path} //= [$haml_args{location}]; # for Perl v5.10
    $haml_args{path} = defined $haml_args{path}
      ? $haml_args{path}
      : [$haml_args{location}];

    return Text::Haml->new(%haml_args);
}

sub render {
    my ($self, $template, $vars) = @_;

    my $haml = $self->engine;
    my $content = $haml->render_file($template, %$vars)
      or croak $haml->error;

    # In the method layout set escape_html in 0 to insert the contents of a page
    # For all other cases set escape_html 1
    $haml->escape_html(1);

    return $content;
}

1;
__END__