File Coverage

blib/lib/Dancer2/Session/PSGI.pm

Criterion	Covered	Total	%
statement	20	21	95.2
branch	4	4	100.0
condition			n/a
subroutine	7	9	77.7
pod	0	3	0.0
total	31	37	83.7

package Dancer2::Session::PSGI;

# ABSTRACT: Dancer2 session storage via Plack::Middleware::Session

use Moo;
with 'Dancer2::Core::Role::SessionFactory';

our $VERSION = '0.010'; # VERSION

#-----------------------------------------#
# Alter SessionFactory attribute defaults
#-----------------------------------------#

has '+cookie_name' => ( default => 'plack_session' );

#-----------------------------------------#
# SessionFactory implementation methods
#-----------------------------------------#

# Get middleware session hash
sub _retrieve {
    shift->request->env->{'psgix.session'};
}

# Put data back/into middleware session hash
sub _flush {
    my ( $self, $id, $data ) = @_;
    $self->request->env->{'psgix.session'} = $data;
}

# Do nothing - we override change_id below but this method must exist to
# force Dance2::Core::App::change_session_id to call our change_id method
sub _change_id {}

# Middleware handles cookie expiry
sub _destroy { return }

# Its the responsibility of Plack::Middleware::Session for
# tracking other sessions (we know nothing about them).
# So return an empty list.
sub _sessions { return [] }

#-----------------------------------------#
# Overridden methods from SessionFactory
#-----------------------------------------#

# Plack::Middleware::Session is responsible for fetch and id generation
# any ID passed to this engine is considered valid
sub validate_id { 1 }

sub change_id {
    my ( $self, %params ) = @_;
    my $session = $params{session};

    $self->execute_hook( 'engine.session.before_change_id', $session->id );
    $self->request->env->{'psgix.session.options'}->{'change_id'} = 1;
    # we don't know what the new session ID will be yet so make it undef
    $self->execute_hook( 'engine.session.before_change_id', undef );
}

# Middleware sets the cookie.
sub set_cookie_header {
    my ( $self, %params ) = @_;

    my $session = $params{session};
    my $options = $self->request->env->{'psgix.session.options'};

    if ( my $expires = $session->expires ) {
        if ( $session->expires < time ) { # Cookie has expired.
            $options->{expire} = 1;
        }
        else { # Pass upstream the cookie expire time
            $options->{expires} = $expires;
        }
    }
}

1;

__END__