File Coverage

blib/lib/Dancer2/Plugin/MobileDevice.pm

Criterion	Covered	Total	%
statement	29	29	100.0
branch	8	8	100.0
condition	4	4	100.0
subroutine	8	8	100.0
pod	2	2	100.0
total	51	51	100.0

package Dancer2::Plugin::MobileDevice;

use strict;
use warnings;

our $VERSION = "0.000001";

=head1 NAME

Dancer2::Plugin::MobileDevice - Make a Dancer2 app mobile-aware

=cut

use Dancer2::Plugin;

plugin_keywords qw(is_mobile_device);

sub is_mobile_device {
    my $self = shift;
    return (($self->app->request->user_agent || '')
        =~ /(?:iP(?:ad|od|hone)|Android|BlackBerry|Mobile|Palm)/) || 0 ;
} #is_mobile_device

sub BUILD {
    my $plugin = shift;

    # Change the layout setting.  Save the old to reset the setting later.
    # We check config->{mobile_layout} within the hook rather than outside
    # so that the plugin will respond correctly if mobile_layout is
    # changed between requests.
    $plugin->app->add_hook(
        Dancer2::Core::Hook->new(
            name => 'before',
            code => sub {
                return unless $plugin->config->{mobile_layout};
                return unless $plugin->is_mobile_device;
                my $mobile_layout = $plugin->config->{mobile_layout};
                $plugin->app->log(debug => "Using mobile layout $mobile_layout");

                $plugin->app->request->var(orig_layout => $plugin->app->setting('layout'));
                $plugin->app->setting(layout => $mobile_layout);
            }
        )
    );

    # After a request, reset the layout for the benefit of future requests.
    # Don't check the state of the request just in case the mobile_layout
    # has changed between the beginning and the end of the request (although
    # I'm not sure how that could happen!).
    $plugin->app->add_hook(
        Dancer2::Core::Hook->new(
            name => 'after',
            code => sub {
                my $vars = $plugin->app->request->vars;
                return unless exists $vars->{orig_layout};
                    # Can't check truthiness, since undef is a valid
                    # orig_layout value.

                $plugin->app->log(debug => "resetting layout to " .
                    ($vars->{orig_layout} || ''));
                $plugin->app->setting(layout => $vars->{orig_layout});
            }
        )
    );

    # Make variable 'is_mobile_device' available in templates
    $plugin->app->add_hook(
        Dancer2::Core::Hook->new(
            name => 'before_template_render',
            code => sub {
                my $tokens = shift;
                $plugin->app->request->var(is_mobile_device => $plugin->is_mobile_device);
                $tokens->{'is_mobile_device'} = $plugin->is_mobile_device;

                $plugin->app->log(debug => 'Requester ' .
                    ($plugin->is_mobile_device ? 'is' : 'is not') .
                    ' mobile device');
            }
        )
    );

} #BUILD

1;
__END__