File Coverage

blib/lib/Dancer2/Plugin/Menu.pm

Criterion	Covered	Total	%
statement	73	73	100.0
branch	13	16	81.2
condition	8	15	53.3
subroutine	13	13	100.0
pod	1	2	50.0
total	108	119	90.7

package Dancer2::Plugin::Menu ;
$Dancer2::Plugin::Menu::VERSION = '0.006';
use 5.010; use strict; use warnings;

# ABSTRACT: Automatically generate an HTML menu for your Dancer2 app

use Storable     'dclone';
use List::Util   'first';
use Data::Dumper 'Dumper';
use HTML::Element;
use Dancer2::Plugin;
use Dancer2::Core::Hook;

plugin_keywords qw ( menu_item );

### ATTRIBUTES ###
# tree is the current active tree with "active" tags
# clean_tree is tree without "active" tags, used to easily reset tree
# html contains HTML generated from the tree

# Separting the HTML from a logical data structure is probably slightly more
# expensive but makes the code cleaner and easier to follow.

has 'tree'       => ( is => 'rw', default => sub { { '/' => { children => {} } } } );
has 'clean_tree' => ( is => 'rw', predicate => 1,);
has 'html'       => ( is => 'rw');
###################

# set up before_template hook to make the menu dynamic using "active" property
sub BUILD {
  my $s = shift;

  $s->app->add_hook (Dancer2::Core::Hook->new (
    name => 'before_template',
    code => sub {

      # reset or init the trees
      $s->has_clean_tree ? $s->tree(dclone $s->clean_tree)
                         : $s->clean_tree(dclone $s->tree);

      # set active menu items
      my $tokens = shift;
      my @segments = split /\//, $tokens->{request}->route->spec_route;
      shift @segments; # get rid of blank segment
      my $tree = $s->tree->{'/'};
      foreach my $segment (@segments) {
        $tree->{children}{$segment}{active} = 1;
        $tree = $tree->{children}{$segment};
      }

      # tear down and regenerate html and send to template
      $s->html( HTML::Element->new('ul') );
      _get_menu($s->tree->{'/'}, $s->html);
      $tokens->{menu} = $s->html->as_HTML('', "\t", {});
    }
  ));
}

# init the tree; called for each route wrapped in the menu_item keyword
sub menu_item {
  my ($s, $xt_data, $route) = @_;
  my @segments = split /\//, $route->spec_route;
  my $tree = $s->tree;
  $segments[0] = '/'; # replace blank segment with root segment

  # add the path segments and associated data to our tree
  while (my $segment = shift @segments) {
    my $title = ucfirst($segment);
    my $weight = 5;
    $xt_data->{title} //= $title;
    print Dumper $xt_data->{title};
    $xt_data->{weight} //= $weight;

    # add xt_data to existig terminal segments, grow the tree otherwise
    if (!@segments && ($s->tree->{$segment} || !$tree->{$segment}{children})) {
      $tree->{$segment} = $xt_data;
      $tree->{$segment}{protected} = 1;  # cannot be changed by a different route
    } elsif (!$s->tree->{$segment} && !$tree->{$segment}{children}) {
      $tree->{$segment}{children} = {};
    }

    # add menu item data to non-protected items
    if (!$tree->{$segment}{protected}) {
      ($title, $weight) = ($xt_data->{title}, $xt_data->{weight}) if !@segments;
      $tree->{$segment}{title} = $title;
      $tree->{$segment}{weight} = $weight;
      $tree->{$segment}{protected} = !@segments;
    }
    $tree = $tree->{$segment}{children};
  }
}

# generate the HTML based on the contents of the tree
sub _get_menu {
  my ($tree, $element) = @_;

  # sort sibling children menu items by weight and then by name
  foreach my $child (
    sort { ( $tree->{children}{$a}{weight} <=> $tree->{children}{$b}{weight} )
      ||   ( $tree->{children}{$a}{title}  cmp $tree->{children}{$b}{title}  )
         } keys %{$tree->{children}} ) {

    # create menu item list element with classes for css styling
    my $li_this = HTML::Element->new('li');
    $li_this->attr(class => $tree->{children}{$child}{active} ? 'active' : '');

    # add HTML elements for menu item; recurse if menu item has children itself
    $li_this->push_content($tree->{children}{$child}{title});
    if ($tree->{children}{$child}{children}) {
      my $ul      = HTML::Element->new('ul');
      $li_this->push_content($ul);
      $element->push_content($li_this);
      _get_menu($tree->{children}{$child}, $ul)
    } else {
      $element->push_content($li_this);
    }
  }
  return $element;
}

1; # Magic true value

__END__