File Coverage

blib/lib/Dancer2/Plugin/Auth/Tiny.pm

Criterion	Covered	Total	%
statement	35	37	94.5
branch	6	8	75.0
condition	1	2	50.0
subroutine	10	10	100.0
pod	0	1	0.0
total	52	58	89.6

use 5.008001;
use strict;
use warnings;

package Dancer2::Plugin::Auth::Tiny;
# ABSTRACT: Require logged-in user for specified routes
our $VERSION = '0.007';

use Carp qw/croak/;

use Dancer2::Plugin;

my $conf;
my %dispatch = ( login => \&_build_login, );

register 'needs' => sub {
    my ( $dsl, $condition, @args ) = plugin_args(@_);

    my $builder = $dispatch{$condition};

    if ( ref $builder eq 'CODE' ) {
        return $builder->( $dsl, @args );
    }
    else {
        croak "Unknown authorization condition '$condition'";
    }
};

sub extend {
    my ( $class, @args ) = @_;
    unless ( @args % 2 == 0 ) {
        croak "arguments to $class\->extend must be key/value pairs";
    }
    %dispatch = ( %dispatch, @args );
}

sub _build_login {
    my ( $dsl, $coderef ) = @_;

    $conf ||= { _default_conf(), %{ plugin_setting() } };

    return sub {
        my $request = $dsl->app->request;
        if ( $dsl->app->session->read( $conf->{logged_in_key} ) ) {
            goto $coderef;
        }
        else {
            my $params = $request->params;
            my $data =
              { $conf->{callback_key} => $request->uri_for( $request->path, $params->{query} ) };
            for my $k ( @{ $conf->{passthrough} } ) {
                $data->{$k} = $params->{$k} if $params->{$k};
            }
            return $dsl->app->redirect( $request->uri_for( $conf->{login_route}, $data ) );
        }
    };
}

sub _default_conf {
    return (
        login_route   => '/login',
        logged_in_key => 'user',
        callback_key  => 'return_url',
        passthrough   => [qw/user/],
    );
}

register_plugin for_versions => [2];

1;


# vim: ts=4 sts=4 sw=4 et:

__END__