File Coverage

blib/lib/Dancer2/Plugin/Adapter.pm

Criterion	Covered	Total	%
statement	31	33	93.9
branch	13	20	65.0
condition	6	7	85.7
subroutine	6	6	100.0
pod			n/a
total	56	66	84.8

use 5.008001;
use strict;
use warnings;

package Dancer2::Plugin::Adapter;
our $AUTHORITY = 'cpan:YANICK';
# ABSTRACT: Wrap any simple class as a service for Dancer2
# VERSION
$Dancer2::Plugin::Adapter::VERSION = '0.007';
use Dancer2::Plugin;
use Class::Load qw/try_load_class/;

my %singletons;
my $conf;

# called with ($dsl, $name, $object)
my %save_by_scope = (
  singleton => sub { $singletons{ $_[1] } = $_[2] },
  request   => sub {
    my $dsl = shift;
    my $hr = $dsl->app->request->var("_dpa") || {};
    $hr->{ $_[0] } = $_[1];
    $dsl->app->request->var( "_dpa", $hr );
  },
  none      => sub { },
);

# called with ($dsl, $name)
my %fetch_by_scope = (
  singleton => sub { $singletons{ $_[1] } },
  request   => sub { my $hr = $_[0]->app->request->var("_dpa") || {}; $hr->{ $_[1] }; },
  none      => sub { },
);

register service => sub {
  my ( $dsl, $name ) = @_;

  unless ($name) {
    die "Dancer2::Plugin::Adapter::service() requires a name argument";
  }

  $conf ||= plugin_setting();

  # ensure service is defined
  my $object_conf = $conf->{$name}
    or die "No configuration for Adapter '$name'";

  # set scope, but default to 'request' if not set
  my $scope = $conf->{$name}{scope} || 'request';
  unless ( $fetch_by_scope{$scope} ) {
    die "Scope '$scope' is invalid";
  }

  # return cached object if already created
  my $cached = $fetch_by_scope{$scope}->($dsl, $name);
  return $cached if defined $cached;

  # otherwise, instantiate the object from config settings
  my $class = $object_conf->{class}
    or die "No class specified for Adapter '$name'";

  try_load_class($class)
    or die "Module '$class' could not be loaded";

  my $new = $object_conf->{constructor} || 'new';
  my $options = $object_conf->{options};

  my @options =
      ref($options) eq 'HASH'  ? %$options
    : ref($options) eq 'ARRAY' ? @$options
    : defined($options) ? $options
    :                     ();

  my $object = eval { $class->$new(@options) }
    or die "Could not create $class object: $@";

  # cache by scope
  $save_by_scope{$scope}->( $dsl, $name, $object );
  return $object;
};

register_plugin for_versions => [ 2 ];

1;


# vim: ts=2 sts=2 sw=2 et:

__END__