File Coverage

blib/lib/Dancer2/Plugin/Adapter.pm

Criterion	Covered	Total	%
statement	18	37	48.6
branch	0	20	0.0
condition	0	7	0.0
subroutine	6	7	85.7
pod			n/a
total	24	71	33.8

use 5.008001;
use strict;
use warnings;

package Dancer2::Plugin::Adapter;
# ABSTRACT: Wrap any simple class as a service for Dancer2
our $VERSION = '0.005'; # VERSION

use Dancer2::Plugin;
use Dancer2 ':syntax';
use Class::Load qw/try_load_class/;

my %singletons;
my $conf;

my %save_by_scope = (
  singleton => sub { $singletons{ $_[0] } = $_[1] },
  request => sub {
    my $hr = var("_dpa") || {};
    $hr->{ $_[0] } = $_[1];
    var( "_dpa", $hr );
  },
  none => sub { },
);

my %fetch_by_scope = (
  singleton => sub { $singletons{ $_[0] } },
  request   => sub { my $hr = var("_dpa") || {}; $hr->{ $_[0] }; },
  none      => sub { },
);

register service => sub {
  my ( $self, $name ) = plugin_args(@_);

  unless ($name) {
    die "Dancer2::Plugin::Adapter::service() requires a name argument";
  }

  $conf ||= plugin_setting();

  # ensure service is defined
  my $object_conf = $conf->{$name}
    or die "No configuration for Adapter '$name'";

  # set scope, but default to 'request' if not set
  my $scope = $conf->{$name}{scope} || 'request';
  unless ( $fetch_by_scope{$scope} ) {
    die "Scope '$scope' is invalid";
  }

  # return cached object if already created
  my $cached = $fetch_by_scope{$scope}->($name);
  return $cached if defined $cached;

  # otherwise, instantiate the object from config settings
  my $class = $object_conf->{class}
    or die "No class specified for Adapter '$name'";

  try_load_class($class)
    or die "Module '$class' could not be loaded";

  my $new = $object_conf->{constructor} || 'new';
  my $options = $object_conf->{options};

  my @options =
      ref($options) eq 'HASH'  ? %$options
    : ref($options) eq 'ARRAY' ? @$options
    : defined($options) ? $options
    :                     ();

  my $object = eval { $class->$new(@options) }
    or die "Could not create $class object: $@";

  # cache by scope
  $save_by_scope{$scope}->( $name, $object );
  return $object;
};

register_plugin for_versions => [ 2 ];

1;


# vim: ts=2 sts=2 sw=2 et:

__END__