File Coverage

blib/lib/Dancer/Template/HtmlTemplate.pm

Criterion	Covered	Total	%
statement	34	36	94.4
branch	6	10	60.0
condition	1	3	33.3
subroutine	8	8	100.0
pod	2	2	100.0
total	51	59	86.4

package Dancer::Template::HtmlTemplate;

use strict;
use warnings;
use Dancer::ModuleLoader;
use Dancer::FileUtils 'path';

use base 'Dancer::Template::Abstract';

our $VERSION = '0.07';


sub init {
    my ($self) = @_;

    die "HTML::Template is needed by Dancer::Template::HtmlTemplate"
      unless Dancer::ModuleLoader->load('HTML::Template');
}

sub render($$$) {
    my ($self, $template, $tokens) = @_;
    die "'$template' is not a regular file"
      if !ref($template) && (!-f $template);

    _flatten($tokens)
      if ref $tokens eq 'HASH';

    my $config = $self->config;
    if ($config->{die_on_bad_params}) {
        Dancer::Logger::warning(
            "Ignoring die_on_bad_params setting supplied - see documentation"
        );
        delete $config->{die_on_bad_params};
    }
    my $ht = HTML::Template->new(
        filename => $template,
        %$config,
        die_on_bad_params => 0, # Required, as we pass through other params too
    );
    $ht->param($tokens);
    return $ht->output;

}

sub _flatten {
    my ($tokens) = @_;
    my @keys = keys %$tokens;
    while (@keys) {
        my $key = shift @keys;
        ref $tokens->{$key} eq 'HASH'
          or next;
        my $value = delete $tokens->{$key};
        my @new_keys = map "$key.$_", keys %$value;
        @$tokens{@new_keys} = values %$value;
        push(@keys, @new_keys);
    }
}

1;
__END__