File Coverage

lib/Dancer/Plugin/UUID.pm

Criterion	Covered	Total	%
statement	27	27	100.0
branch	3	4	75.0
condition			n/a
subroutine	10	10	100.0
pod			n/a
total	40	41	97.5

package Dancer::Plugin::UUID;

#ABSTRACT: Maintain unique identifiers for each visitor of the application.


use strict;
use warnings;
use feature ':5.10';
use Dancer ':syntax';
use Dancer::Plugin;
use Digest::SHA1 'sha1_hex';
use Data::UUID;

# constants
my $uuid_cookie_name = 'dancer.uuid';
my $drop_test_name   = 'dancer.uuid.test';

hook 'before' => sub {

    # if Do Not Track, do nothing
    return if request->env->{'HTTP_DNT'};

    # if we have a UUID already, return
    my $uuid = cookies->{$uuid_cookie_name};
    return if defined $uuid;

    # no UUID cookie is found, do we have the 'test cookie'?
    if ( defined cookies->{$drop_test_name} ) {

        # check the value, to make sure that's our cookie
        my $expected = _build_test_cookie_value();

        # the test cookie has the expected value, we can drop our UUID cookie
        if ( $expected eq cookies->{$drop_test_name}->value ) {
            my $uuid_fact = Data::UUID->new;
            $uuid = $uuid_fact->create();
            cookie $uuid_cookie_name => $uuid_fact->to_string($uuid),
              expires                => "3 years";
        }
    }

    # drop the test cookie, for the session
    cookie $drop_test_name => _build_test_cookie_value();
};

register uuid => sub {
    return _uuid_value();
};

hook 'before_template_render' => sub {
    my $tokens = shift;
    $tokens->{'dancer.uuid'} = _uuid_value();
};

# private

sub _build_test_cookie_value {
    return sha1_hex( __FILE__ );
}

sub _uuid_value {
    if ( !request->env->{HTTP_DNT} ) {
        my $uuid = cookies->{$uuid_cookie_name};
        return $uuid->value if defined $uuid;
    }
    undef;
}

register_plugin;
1;

__END__