File Coverage

blib/lib/DDG/Meta/ShareDir.pm

Criterion	Covered	Total	%
statement	43	52	82.6
branch	5	18	27.7
condition	1	3	33.3
subroutine	10	12	83.3
pod	1	3	33.3
total	60	88	68.1

package DDG::Meta::ShareDir;
our $AUTHORITY = 'cpan:DDG';
# ABSTRACT: Installing functions for easy access to the module sharedir
$DDG::Meta::ShareDir::VERSION = '1016';
use strict;
use warnings;
use Carp qw( croak );
use Module::Data;
use Path::Class;
use Package::Stash;
use File::ShareDir ':ALL';

require Moo::Role;


my %applied;

sub apply_keywords {
	my ( $class, $target ) = @_;

	return if exists $applied{$target};
	$applied{$target} = undef;

	my @parts = split('::',$target);
	shift @parts;
	unshift @parts, 'share';
	my $share_path = join('/',map { s/([a-z])([A-Z])/$1_$2/g; lc; } @parts);

	my $moddata = Module::Data->new($target);
	my $basedir = $moddata->root->parent;

	my $share;

	if ( get_lib($basedir) and get_share($basedir) ) {
		my $dir = dir($basedir,$share_path);
		$share = $dir if -d $dir;
	} else {
		eval {
			my $dir = module_dir($target);
			$share = dir($dir) if -d $dir;
		}
	}

	if ($share) {
		my $stash = Package::Stash->new($target);


		$stash->add_symbol('&share', sub {
			@_ ? -d dir($share,@_)
				? $share->subdir(@_)
				: $share->file(@_)
			: $share
		});


		$stash->add_symbol('&module_share_dir', sub { $share_path });

		#
		# apply role
		#

		Moo::Role->apply_role_to_package($target,'DDG::HasShareDir');
	}

}

# Temporarily add support for both `subdir` and `child` methods
# to ensure backwards compatibilty while we upgrade Module::Data
# throughout our stack
# More info: https://github.com/duckduckgo/duckduckgo/pull/244
sub get_lib {
	my $basedir = shift;
	return -e $basedir->subdir('lib') if $basedir->can('subdir');
	return -e $basedir->child('lib');
}

sub get_share {
	my $basedir = shift;
	return -e $basedir->subdir('share') if $basedir->can('subdir');
	return -e $basedir->child('share');
}
1;

__END__