File Coverage

blib/lib/DBIx/HTML.pm

Criterion	Covered	Total	%
statement	15	46	32.6
branch	0	14	0.0
condition	0	9	0.0
subroutine	5	10	50.0
pod	2	2	100.0
total	22	81	27.1

package DBIx::HTML;
use strict;
use warnings FATAL => 'all';
our $VERSION = '1.02';
our $AUTOLOAD;

use DBI;
use Carp;
use Spreadsheet::HTML;

sub connect {
    my $class = shift;
    my $self = {
        head        => [],
        rows        => [],
        dbh         => undef,
        sth         => undef,
        keep_alive  => undef,
        generator   => Spreadsheet::HTML->new(
            headings => sub { join(' ', map { ucfirst(lc($_)) } split ('_', shift || '')) }
        ),
    };

    if (UNIVERSAL::isa( $_[0], 'DBI::db' )) {
        # use supplied db handle
        $self->{dbh}        = $_[0];
        $self->{keep_alive} = 1;
    } else {
        # create my own db handle
        eval { $self->{dbh} = DBI->connect( @_ ) };
        croak $@ and return undef if $@;
    }

    return bless $self, $class;
}

sub do {
    my $self = shift;
    my ($sql, $args) = @_;

    croak "can't call do(): no database handle" unless $self->{dbh};

    eval {
        $self->{sth} = $self->{dbh}->prepare( $sql );
        $self->{sth}->execute( @$args );
    };
    croak $@ and return undef if $@;

    $self->{head} = $self->{sth}{NAME};
    $self->{rows} = $self->{sth}->fetchall_arrayref;
    $self->{generator}{data} = [ $self->{head}, @{ $self->{rows} } ];
    return $self;
}

sub AUTOLOAD {
    my $self = shift;
    croak "must connect() first" unless $self->isa( __PACKAGE__ );
    (my $method = $AUTOLOAD) =~ s/.*:://;
    croak "no such method $method for " . ref($self->{generator}) unless $self->{generator}->can( $method );
    return $self->{generator}->$method( @_ );
}

# disconnect database handle if i created it
sub DESTROY {
    my $self = shift;
    if (!$self->{keep_alive} and $self->{dbh}->isa( 'DBI::db' )) {
        $self->{dbh}->disconnect();
    }
}

1;
__END__