File Coverage

blib/lib/DBIx/DBHResolver/Strategy/Range.pm

Criterion	Covered	Total	%
statement	35	40	87.5
branch	7	10	70.0
condition	1	3	33.3
subroutine	6	7	85.7
pod	2	2	100.0
total	51	62	82.2

package DBIx::DBHResolver::Strategy::Range;

use strict;
use warnings;
use parent qw(DBIx::DBHResolver::Strategy);
use Carp;
use Data::Util qw(is_array_ref neat);

our $VERSION = '0.01';
our %OPS     = (
    '>'  => sub { ( $_[0] > $_[1] )  ? 1 : 0 },
    '>=' => sub { ( $_[0] >= $_[1] ) ? 1 : 0 },
    '<'  => sub { ( $_[0] < $_[1] )  ? 1 : 0 },
    '<=' => sub { ( $_[0] <= $_[1] ) ? 1 : 0 },
    '==' => sub { ( $_[0] == $_[1] ) ? 1 : 0 },
);

sub connect_info {
    my ( $class, $resolver, $node_or_cluster, $args ) = @_;

    my ($resolved_node, @keys) =
      $class->resolve( $resolver, $node_or_cluster, $args );

    return $resolver->connect_info( $resolved_node, \@keys );
}

sub resolve {
    my ( $class, $resolver, $node_or_cluster, $args ) = @_;

    my @keys = $class->keys_from_args($args);
    my $key = shift @keys;

    unless ( exists $args->{strategy_config}
        && is_array_ref( $args->{strategy_config} ) )
    {
        croak 'strategy_config is not exists or is not array ref';
    }

    my $resolved_node;
    my @range_stmts = @{ $args->{strategy_config} };
    while ( my ( $range_node, $range_stmt ) = splice( @range_stmts, 0, 2 ) ) {
        my %op_values       = @$range_stmt;
        my $is_matched_stmt = 1;
        for my $op ( keys %op_values ) {
            croak sprintf('No supported operator (%s)', neat($op)) unless ( exists $OPS{$op});
            unless ( $OPS{$op}->( $key, $op_values{$op} ) ) {
                $is_matched_stmt = 0;
                last;
            }
        }
        if ($is_matched_stmt) {
            $resolved_node = $range_node;
            last;
        }
    }

    unless ( defined $resolved_node ) {
        croak sprintf( 'No matched range (key: %f)', $key );
    }

    return ($resolved_node, @keys);
}

1;

__END__