File Coverage

blib/lib/DBIx/Class/QueryLog/Conditional.pm

Criterion	Covered	Total	%
statement	19	19	100.0
branch	2	2	100.0
condition			n/a
subroutine	13	13	100.0
pod	0	8	0.0
total	34	42	80.9

package DBIx::Class::QueryLog::Conditional;
$DBIx::Class::QueryLog::Conditional::VERSION = '0.001000';
# ABSTRACT: Disable QueryLogger instead of all query logging

use Moo;
use warnings NONFATAL => 'all';

use Sub::Name 'subname';

my @methods = qw(
   txn_begin txn_commit txn_rollback
   svp_begin svp_release svp_rollback
   query_start query_end
);
sub _valid_logger { !$_[0]->can($_) && return 0 for @methods; 1 }

use namespace::clean;

has _logger => (
   is => 'ro',
   isa => sub { die 'not a valid logger' unless _valid_logger($_[0]) },
   init_arg => 'logger',
   required => 1,
);

has enabled => (
   is => 'rw',
   default => 1,
);

has _enabled_method => (
   is => 'ro',
   init_arg => 'enabled_method',
   default => sub {
      sub { shift->enabled }
   },
);

for my $method (@methods) {
   no strict 'refs';
   *{$method} = subname $method => sub {
      my $self = shift;

      my $m = $self->_enabled_method ;
      return unless $self->$m;

      $self->_logger->$method(@_);
   };
}

1;

__END__