File Coverage

blib/lib/DBIx/Class/InflateColumn/Authen/Passphrase.pm

Criterion	Covered	Total	%
statement	21	21	100.0
branch	3	4	75.0
condition	2	3	66.6
subroutine	7	7	100.0
pod	1	1	100.0
total	34	36	94.4

use strict;
use warnings;

package DBIx::Class::InflateColumn::Authen::Passphrase; # git description: v0.02-2-gdc402d1
# ABSTRACT: Inflate/deflate columns to Authen::Passphrase instances

our $VERSION = '0.03';

use Authen::Passphrase;
use parent 'DBIx::Class';

#pod =head1 SYNOPSIS
#pod
#pod     __PACKAGE__->load_components(qw(InflateColumn::Authen::Passphrase));
#pod
#pod     __PACKAGE__->add_columns(
#pod         id => {
#pod             data_type         => 'integer',
#pod             is_auto_increment => 1,
#pod         },
#pod         passphrase_rfc2307 => {
#pod             data_type          => 'text',
#pod             inflate_passphrase => 'rfc2307',
#pod         },
#pod         passphrase_crypt => {
#pod             data_type          => 'text',
#pod             inflate_passphrase => 'crypt',
#pod         },
#pod     );
#pod
#pod     __PACKAGE__->set_primary_key('id');
#pod
#pod
#pod     # in application code
#pod     $rs->create({ passphrase_rfc2307 => Authen::Passphrase::RejectAll->new });
#pod
#pod     my $row = $rs->find({ id => $id });
#pod     if ($row->passphrase_rfc2307->match($input)) { ...
#pod
#pod =head1 DESCRIPTION
#pod
#pod Provides inflation and deflation for Authen::Passphrase instances from and to
#pod either RFC 2307 or crypt encoding.
#pod
#pod To enable both inflating and deflating, C must be set to a
#pod valid passphrase encoding. Currently the only supported encodings are C
#pod and C. The specified encoding will be used both when storing
#pod C instances in columns, and when creating
#pod C instances from columns. See L for
#pod details on passphrase encodings.
#pod
#pod Note that not all passphrase schemes supported by C can be
#pod represented in either RFC 2307 or crypt encoding. Chose the kind of passphrase
#pod encoding you're using based on the encoding supported by the passphrase algorithms
#pod you're using.
#pod
#pod When trying to encode a passphrase instance with an encoding that doesn't
#pod support it, an exception will be thrown. Similarly, when trying to load a
#pod passphrase instance from a faulty or unknown encoded representation, an
#pod exception will be thrown.
#pod
#pod =method register_column
#pod
#pod Chains with the C method in C, and sets up
#pod passphrase columns appropriately. This would not normally be directly called by
#pod end users.
#pod
#pod =cut

sub register_column {
    my ($self, $column, $info, @rest) = @_;

    $self->next::method($column, $info, @rest);
    return unless my $encoding = $info->{inflate_passphrase};

    $self->throw_exception(q['rfc2307' and 'crypt' are the only supported types of passphrase columns])
        unless $encoding eq 'rfc2307' || $encoding eq 'crypt';

    $self->inflate_column(
        $column => {
            inflate => sub { Authen::Passphrase->${\"from_${encoding}"}(shift) },
            deflate => sub { shift->${\"as_${encoding}"} },
        },
    );
}

1;

__END__