File Coverage

blib/lib/DBIx/Class/Helper/SimpleStats.pm

Criterion	Covered	Total	%
statement	50	51	98.0
branch	7	10	70.0
condition	2	3	66.6
subroutine	10	10	100.0
pod	1	1	100.0
total	70	75	93.3

package DBIx::Class::Helper::SimpleStats;

# ABSTRACT: Simple grouping and aggregate functions for DBIx::Class

use v5.10.1;

use strict;
use warnings;

use base qw( DBIx::Class );

use Carp;
use List::Util 1.45 qw/ uniqstr /;
use Ref::Util qw/ is_plain_hashref is_ref /;

# RECOMMEND PREREQ: Ref::Util::XS

use namespace::autoclean;

our $VERSION = 'v0.1.2';



sub simple_stats {
    my ( $self, @args ) = @_;

    croak "No columns" unless @args;

    my @cols;
    my @funcs;

    my $me = $self->current_source_alias;

    my $alias = sub {
      my $ident = shift;
      $ident = "$me.$ident" unless $ident =~ /^(\w+)\./;
      return $ident;
    };

    foreach my $arg (@args) {

        if ( is_ref($arg) ) {

            if ( is_plain_hashref($arg) ) {

                my $as = delete $arg->{'-as'};
                my ( $func, $col ) = each %{$arg};

                $as //= "${col}_${func}";

                push @cols, $alias->($col);

                push @funcs, { $func => $alias->($col), -as => $as };

            }
            else {

                croak "Unsupported reference type: " . ref($arg);

            }

        }
        else {

            push @cols, $alias->($arg);

        }

    }

    unless (@funcs) {

        my $func = "count";
        my $col  = $cols[0];
        $col =~ s/^\w+\.// ;

        push @funcs, { $func => $alias->($col), -as => "${col}_${func}" };

    }

    my @names = map { delete $_->{'-as'} } @funcs;

    my @group = uniqstr @cols;

    return $self->search(
        undef,
        {
            group_by => \@group,
            select  => [ @group, @funcs ],
            as      => [ @group, @names ],
            order_by => \@group,
        }
    );

}




1;

__END__