File Coverage

blib/lib/DBIx/Class/CDBICompat/Relationships.pm

Criterion	Covered	Total	%
statement	24	121	19.8
branch	0	44	0.0
condition	0	34	0.0
subroutine	8	22	36.3
pod	0	6	0.0
total	32	227	14.1

package # hide from PAUSE
    DBIx::Class::CDBICompat::Relationships;

use strict;
use warnings;
use base 'DBIx::Class';

use Clone;
use DBIx::Class::CDBICompat::Relationship;
use Scalar::Util 'blessed';
use DBIx::Class::_Util qw(quote_sub perlstring);
use namespace::clean;

__PACKAGE__->mk_classdata('__meta_info' => {});


=head1 NAME

DBIx::Class::CDBICompat::Relationships - Emulate has_a(), has_many(), might_have() and meta_info()

=head1 DESCRIPTION

Emulate C, C, C and C.

=cut

sub has_a {
    my($self, $col, @rest) = @_;

    $self->_declare_has_a($col, @rest);
    $self->_mk_inflated_column_accessor($col);

    return 1;
}


sub _declare_has_a {
  my ($self, $col, $f_class, %args) = @_;
  $self->throw_exception( "No such column ${col}" )
   unless $self->has_column($col);
  $self->ensure_class_loaded($f_class);

  my $rel_info;

  # Class::DBI allows Non database has_a with implicit deflate and inflate
  # Hopefully the following will catch Non-database tables.
  if( !$f_class->isa('DBIx::Class::Row') and !$f_class->isa('Class::DBI::Row') ) {
    $args{'inflate'} ||= sub { $f_class->new(shift) }; # implicit inflate by calling new
    $args{'deflate'} ||= sub { shift() . '' }; # implicit deflate by stringification
  }

  if ($args{'inflate'} || $args{'deflate'}) { # Non-database has_a
    if (!ref $args{'inflate'}) {
      my $meth = $args{'inflate'};
      $args{'inflate'} = sub { $f_class->$meth(shift); };
    }
    if (!ref $args{'deflate'}) {
      my $meth = $args{'deflate'};
      $args{'deflate'} = sub { shift->$meth; };
    }
    $self->inflate_column($col, \%args);

    $rel_info = {
        class => $f_class
    };
  }
  else {
    $self->belongs_to($col, $f_class);
    $rel_info = $self->result_source->relationship_info($col);
  }

  $rel_info->{args} = \%args;

  $self->_extend_meta(
    has_a => $col,
    $rel_info
  );

  return 1;
}

sub _mk_inflated_column_accessor {
    my($class, $col) = @_;

    return $class->mk_group_accessors('inflated_column' => $col);
}

sub has_many {
  my ($class, $rel, $f_class, $f_key, $args) = @_;

  my @f_method;

  if (ref $f_class eq 'ARRAY') {
    ($f_class, @f_method) = @$f_class;
  }

  if (ref $f_key eq 'HASH' && !$args) { $args = $f_key; undef $f_key; };

  $args ||= {};
  my $cascade = delete $args->{cascade} || '';
  if (delete $args->{no_cascade_delete} || $cascade eq 'None') {
    $args->{cascade_delete} = 0;
  }
  elsif( $cascade eq 'Delete' ) {
    $args->{cascade_delete} = 1;
  }
  elsif( length $cascade ) {
    warn "Unemulated cascade option '$cascade' in $class->has_many($rel => $f_class)";
  }

  if( !$f_key and !@f_method ) {
      $class->ensure_class_loaded($f_class);
      my $f_source = $f_class->result_source;
      ($f_key) = grep { $f_source->relationship_info($_)->{class} eq $class }
                      $f_source->relationships;
  }

  $class->next::method($rel, $f_class, $f_key, $args);

  my $rel_info = $class->result_source->relationship_info($rel);
  $args->{mapping}      = \@f_method;
  $args->{foreign_key}  = $f_key;
  $rel_info->{args} = $args;

  $class->_extend_meta(
    has_many => $rel,
    $rel_info
  );

  if (@f_method) {
    my @qsub_args = (
      { '$rf' => \sub { my $o = shift; $o = $o->$_ for @f_method; $o } },
      { attributes => [ 'DBIC_method_is_generated_from_resultsource_metadata' ] },
    );

    quote_sub "${class}::${rel}", sprintf( <<'EOC', perlstring $rel), @qsub_args;
      my $rs = shift->related_resultset(%s)->search_rs( @_);
      $rs->{attrs}{record_filter} = $rf;
      return (wantarray ? $rs->all : $rs);
EOC

    return 1;
  }
}


sub might_have {
  my ($class, $rel, $f_class, @columns) = @_;

  my $ret;
  if (ref $columns[0] || !defined $columns[0]) {
    $ret = $class->next::method($rel, $f_class, @columns);
  } else {
    $ret = $class->next::method($rel, $f_class, undef,
                                { proxy => \@columns });
  }

  my $rel_info = $class->result_source->relationship_info($rel);
  $rel_info->{args}{import} = \@columns;

  $class->_extend_meta(
    might_have => $rel,
    $rel_info
  );

  return $ret;
}


sub _extend_meta {
    my ($class, $type, $rel, $val) = @_;

### Explicitly not using the deep cloner as Clone exhibits specific behavior
### wrt CODE references - it simply passes them as-is to the new structure
### (without deparse/eval cycles). There likely is code that relies on this
### so we just let sleeping dogs lie.
    my $hash = Clone::clone($class->__meta_info || {});

    $val->{self_class} = $class;
    $val->{type}       = $type;
    $val->{accessor}   = $rel;

    $hash->{$type}{$rel} = DBIx::Class::CDBICompat::Relationship->new($val);
    $class->__meta_info($hash);
}


sub meta_info {
    my ($class, $type, $rel) = @_;
    my $meta = $class->__meta_info;
    return $meta unless $type;

    my $type_meta = $meta->{$type};
    return $type_meta unless $rel;
    return $type_meta->{$rel};
}


sub search {
  my $self = shift;
  my $attrs = {};
  if (@_ > 1 && ref $_[-1] eq 'HASH') {
    $attrs = { %{ pop(@_) } };
  }
  my $where = (@_ ? ((@_ == 1) ? ((ref $_[0] eq "HASH") ? { %{+shift} } : shift)
                               : {@_})
                  : undef());
  if (ref $where eq 'HASH') {
    foreach my $key (keys %$where) { # has_a deflation hack
      $where->{$key} = ''.$where->{$key} if (
        defined blessed $where->{$key}
          and
        $where->{$key}->isa('DBIx::Class')
      );
    }
  }
  $self->next::method($where, $attrs);
}

sub new_related {
  $_[0]->throw_exception("Calling new_related() as a class method is not supported")
    unless length ref $_[0];

  shift->next::method(@_);
}

=head1 FURTHER QUESTIONS?

Check the list of L.

=head1 COPYRIGHT AND LICENSE

This module is free software L
by the L. You can
redistribute it and/or modify it under the same terms as the
L.

=cut

1;