File Coverage

blib/lib/DBD/SQLite/FTS3Transitional.pm

Criterion	Covered	Total	%
statement	28	28	100.0
branch	6	6	100.0
condition	3	3	100.0
subroutine	6	6	100.0
pod	1	1	100.0
total	44	44	100.0

package DBD::SQLite::FTS3Transitional;

use 5.006;
use strict;
use warnings;
no warnings 'uninitialized';
use Exporter ();

our $VERSION   = '1.00';
our @ISA       = 'Exporter';
our @EXPORT_OK = qw/fts3_convert/;

sub fts3_convert {
  my $in  = shift;
  my $out = "";

  # decompose input string into tokens
  my @tokens = $in =~ / -       # minus sign
                      | \bOR\b  # OR keyword
                      | ".*?"   # phrase query
                      | \S+     # term
                      /xg;

  # build the output string
  while (@tokens) {

    # -a => (NOT a)
    if ($tokens[0] eq '-') {
      my (undef, $right) = splice(@tokens, 0, 2);
      $out .= " (NOT $right)";
    }

    # a OR b => (a OR b)
    elsif (@tokens >= 2 && $tokens[1] eq 'OR') {
      my ($left, undef, $right) = splice(@tokens, 0, 3);
      if ($right eq '-') {
        $right = "NOT " . shift @tokens;
      }
      $out .= " ($left OR $right)";
    }

    # plain term
    else {
      $out .= " " . shift @tokens;
    }
  }

  return $out;
}


1;

__END__