File Coverage

lib/DB/Transaction.pm

Criterion	Covered	Total	%
statement	29	29	100.0
branch	15	16	93.7
condition	5	5	100.0
subroutine	4	4	100.0
pod	1	1	100.0
total	54	55	98.1

use strict;
use warnings;
package DB::Transaction;
use base qw(Exporter);

our $VERSION = 0.001001; # 0.001.0

our @EXPORT_OK = qw(run_in_transaction);

my %on_error_options = (
	rollback => undef,
	continue => undef,
);

my %transactions_deep;
sub run_in_transaction (&;@) {
	my $code = shift;
	my (%args) = @_;

	my $db_handle = $args{db_handle};
	my $on_error = $args{on_error} || 'rollback';

	die "Don't know how to handle error action '$on_error'\n"
		if ! exists $on_error_options{$on_error};

	local $db_handle->{AutoCommit} = 0;
	local $db_handle->{RaiseError} = 1;

	$transactions_deep{"$db_handle"}++;
	my $error;
	eval {
		$code->();
		$db_handle->commit if $transactions_deep{"$db_handle"} <= 1;
	;1 } || do {
		$error = defined $@ ? $@ : 'an error was encountered in your transaction';
		$db_handle->rollback if $on_error eq 'rollback';
	};
	$@ = $error if defined $error;
	$transactions_deep{"$db_handle"}--;
	delete $transactions_deep{"$db_handle"} if $transactions_deep{"$db_handle"} < 1;

	die $error if defined $error && $on_error eq 'rollback';

	return ! defined $error;
}

1;

__END__