File Coverage

blib/lib/Curses/UI/AnyEvent.pm

Criterion	Covered	Total	%
statement	27	49	55.1
branch	1	4	25.0
condition	2	8	25.0
subroutine	9	12	75.0
pod	2	6	33.3
total	41	79	51.9

package Curses::UI::AnyEvent;

our $VERSION = '0.101';

use strict;

use AnyEvent;
use base qw( Curses::UI );



sub startAsync {
    my $self = shift;

    $self->do_one_event;

    $self->{_async_watcher} = AE::io \*STDIN, 0, sub {
        $self->do_one_event($self->{_modal_object});

        if (defined $self->{_modal_object} && defined $self->{_modalfocus_cv} && !$self->{_modal_object}->{-has_modal_focus}) {
            $self->{_modalfocus_cv}->send();
        }
    };
}

sub stopAsync {
    my $self = shift;

    delete $self->{_async_watcher};
}

sub mainloop {
    my $self = shift;

    $self->startAsync();

    $self->{_cv} = AE::cv;
    $self->{_cv}->recv;
    delete $self->{_cv};

    $self->stopAsync();
}

sub mainloopExit {
    my $self = shift;

    if (exists $self->{_cv}) {
        $self->{_cv}->send();
    } else {
        warn "Called mainloopExit but mainloop wasn't running";
    }
}

sub char_read {
    my $self = shift;

    $self->Curses::UI::Common::char_read(0); ## Ignore timeout passed in to us, hard-code to 0
}


sub tempdialog() {
    my $self = shift;
    my $class = shift;
    my %args = @_;

    my $cb = delete $args{-cb} || sub {};

    my $id = "__window_$class";

    my $dialog = $self->add($id, $class, %args);

    $self->{_modalfocus_cv} = AE::cv;
    $self->{_modal_object} = $dialog;

    # "Fake" focus for this object.
    $dialog->{-has_modal_focus} = 1;
    $dialog->focus;
    $dialog->draw;

    $self->{_modalfocus_cv}->cb(sub {
        delete $self->{_modalfocus_cv};
        delete $self->{_modal_object};

        $dialog->{-focus} = 0;
        $dialog->{-has_modal_focus} = 0;

        my $return = $dialog->get;
        $self->delete($id);
        $self->root->focus(undef, 1);

        $cb->($return);
    });
}


1;



__END__