File Coverage

blib/lib/Curio/Role.pm

Criterion	Covered	Total	%
statement	46	53	86.7
branch	10	12	83.3
condition			n/a
subroutine	20	23	86.9
pod	10	10	100.0
total	86	98	87.7

package Curio::Role;
our $VERSION = '0.09';

=encoding utf8

=head1 NAME

Curio::Role - Role for Curio classes.

=head1 DESCRIPTION

This L provides various shortcut methods for interacting
witht the underlying L object.

=cut

use Curio::Factory;
use Curio::Util;
use Package::Stash;

use Moo::Role;
use strictures 2;
use namespace::clean;

my %is_exporter_setup;

sub import {
    my ($class) = @_;

    my $factory = $class->factory();
    return if !$factory;

    my $name = $factory->export_function_name();
    return if !defined $name;

    if (!$is_exporter_setup{ $class }) {
        my $stash = Package::Stash->new( $class );

        $stash->add_symbol(
            "&$name",
            $factory->export_resource()
                ? subname( $name, _build_export_resource( $factory ) )
                : subname( $name, _build_export_curio( $factory ) ),
        ) if !$class->can($name);

        $stash->add_symbol(
            $factory->always_export() ? '@EXPORT' : '@EXPORT_OK',
            [ $name ],
        );

        $is_exporter_setup{ $class } = 1;
    }

    goto &Exporter::import;
}

sub _build_export_curio {
    my $factory = shift;
    return sub{ $factory->fetch_curio( @_ ) };
}

sub _build_export_resource {
    my $factory = shift;
    return sub{ $factory->fetch_resource( @_ ) };
}

=head1 CLASS METHODS

=head2 fetch

    my $curio = Some::Curio::Class->fetch();
    my $curio = Some::Curio::Class->fetch( $key );

This proxies to L.

=cut

# The real fetch method is installed in the curio class by:
# Curio::Factory::_install_fetch_method()
sub fetch { undef }

=head2 find_curio

    my $curio_object = MyApp::Service::Cache->find_curio( $resource );

This proxies to L.

=cut

sub find_curio {
    my $class = shift;
    return $class->factory->find_curio();
}

=head2 inject

    MyApp::Service::Cache->inject( $curio_object );
    MyApp::Service::Cache->inject( $key, $curio_object );

This proxies to L.

=cut

sub inject {
    my $class = shift;
    return $class->factory->inject( @_ );
}

=head2 inject_with_guard

    my $guard = MyApp::Service::Cache->inject_with_guard(
        $curio_object,
    );

    my $guard = MyApp::Service::Cache->inject_with_guard(
        $key, $curio_object,
    );

This proxies to L.

=cut

sub inject_with_guard {
    my $class = shift;
    return $class->factory->inject_with_guard( @_ );
}

=head2 clear_injection

    my $curio_object = MyApp::Service::Cache->clear_injection();
    my $curio_object = MyApp::Service::Cache->clear_injection( $key );

This proxies to L.

=cut

sub clear_injection {
    my $class = shift;
    return $class->factory->clear_injection( @_ );
}

=head2 injection

    my $curio_object = MyApp::Service::Cache->injection();
    my $curio_object = MyApp::Service::Cache->injection( $key );

This proxies to L.

=cut

sub injection {
    my $class = shift;
    return $class->factory->injection( @_ );
}

=head2 has_injection

    if (MyApp::Service::Cache->has_injection()) { ... }
    if (MyApp::Service::Cache->has_injection( $key )) { ... }

This proxies to L.

=cut

sub has_injection {
    my $class = shift;
    return $class->factory->has_injection( @_ );
}

=head2 initialize

Sets up your class's L object and is automatically
called when you C.  This is generally not called
directly by end-user code.

=cut

sub initialize {
    Curio::Factory->new( class => shift );
    return;
}

=head1 CLASS ATTRIBUTES

=head2 factory

    my $factory = MyApp::Service::Cache->factory();

Returns the class's L object.

=cut

# The real factory attribute is installed in the curio class by:
# Curio::Factory::_install_factory_method()
sub factory { undef }

=head2 declared_keys

    my $keys = MyApp::Service::Cache->declared_keys();
    foreach my $key (@$keys) { ... }

This proxies to L.

=cut

sub declared_keys {
    my $class = shift;
    return $class->factory->declared_keys( @_ );
}

1;
__END__