File Coverage

blib/lib/Curio/Declare.pm

Criterion	Covered	Total	%
statement	45	45	100.0
branch	2	2	100.0
condition			n/a
subroutine	13	13	100.0
pod			n/a
total	60	60	100.0

package Curio::Declare;
our $VERSION = '0.09';

use Package::Stash;
use Curio::Util;

use strictures 2;
use namespace::clean;

my %EXPORTS = (
    does_registry          => 'bool',
    resource_method_name   => 'string',
    installs_curio_method  => 'bool',
    does_caching           => 'bool',
    cache_per_process      => 'bool',
    export_function_name   => 'string',
    always_export          => 'bool',
    export_resource        => 'bool',
    allow_undeclared_keys  => 'bool',
    default_key            => 'string',
    key_argument           => 'string',
    default_arguments      => 'hashref',
    add_key                => 'method',
    alias_key              => 'method',
);

sub import {
    my $target = caller;

    my $stash = Package::Stash->new( $target );

    foreach my $sub_name (sort keys %EXPORTS) {
        my $type = $EXPORTS{ $sub_name };
        my $builder = "_build_$type\_sub";
        my $sub = __PACKAGE__->can( $builder )->( $target, $sub_name );
        $sub = subname( $sub_name, $sub );
        $stash->add_symbol( "&$sub_name", $sub );
    }

    return;
}

sub _build_string_sub {
    my ($target, $sub_name) = @_;

    return sub{
        my $factory = $target->factory();
        @_ = ( $factory, shift );
        goto &{ $factory->can( $sub_name ) };
    };
}

sub _build_bool_sub {
    my ($target, $sub_name) = @_;

    return sub{
        my $factory = $target->factory();
        @_ = ( $factory, (@_ ? shift : 1 ) );
        goto &{ $factory->can( $sub_name ) };
    };
}

sub _build_hashref_sub {
    my ($target, $sub_name) = @_;

    return sub{
        my $factory = $target->factory();
        @_ = ( $factory, {@_} );
        goto &{ $factory->can( $sub_name ) };
    };
}

sub _build_method_sub {
    my ($target, $sub_name) = @_;

    return sub{
        my $factory = $target->factory();
        @_ = ( $factory, @_ );
        goto &{ $factory->can( $sub_name ) };
    };
}

1;
__END__