File Coverage

blib/lib/Crypt/Scrypt.pm

Criterion	Covered	Total	%
statement	34	36	94.4
branch	15	24	62.5
condition	3	10	30.0
subroutine	7	7	100.0
pod	3	3	100.0
total	62	80	77.5

package Crypt::Scrypt;

use strict;
use warnings;

use Carp qw(croak);
use XSLoader;

our $VERSION    = '0.05';
our $XS_VERSION = $VERSION;
$VERSION = eval $VERSION;

XSLoader::load(__PACKAGE__, $XS_VERSION);

my @errors = (
   'success',
   'getrlimit or sysctl(hw.usermem) failed',
   'clock_getres or clock_gettime failed',
   'error computing derived key',
   'could not read salt from /dev/urandom',
   'error in OpenSSL',
   'malloc failed',
   'data is not a valid scrypt-encrypted block',
   'unrecognized scrypt format',
   'decrypting input would take too much memory',
   'decrypting input would take too long',
   'key is incorrect',
   'error writing output file',
   'error reading input file',
);

my %defaults = (
    max_mem      => 0,
    max_mem_frac => 0.125,
    max_time     => 5,
);

sub new {
    my ($class, @params) = @_;
    my %params = (@params % 2) ? (key => @params) : @params;

    croak q('key' is required) unless defined $params{key};

    return bless \%params, $class;
}

sub encrypt {
    my ($self, $data, @params) = @_;
    my %params = (@params % 2) ? (key => @params) : @params;

    croak 'plaintext must be a scalar or scalar ref'
        if ref $data and 'SCALAR' ne ref $data;

    if (ref $self) {
        %params = (%defaults, %$self, %params);
    }
    else {
        croak q('key' is required) unless defined $params{key};
        %params = (%defaults, %params);
    }

    my ($status, $out) = _encrypt(
        $data, @params{qw(key max_mem max_mem_frac max_time)},
    );
    croak $errors[$status] || 'unknown scrypt error' if $status;

    return $out;
}

sub decrypt {
    my ($self, $data, @params) = @_;
    my %params = (@params % 2) ? (key => @params) : @params;

    croak 'ciphertext must be a scalar or scalar ref'
        if ref $data and 'SCALAR' ne ref $data;

    if (ref $self) {
        %params = (%defaults, %$self, %params);
    }
    else {
        croak q('key' is required) unless defined $params{key};
        %params = (%defaults, %params);
    }

    my ($status, $out) = _decrypt(
        $data, @params{qw(key max_mem max_mem_frac max_time)},
    );
    croak $errors[$status] || 'unknown scrypt error' if $status;

    return $out;
}


1;

__END__