File Coverage

blib/lib/Crypt/Random/Source/Weak/openssl.pm

Criterion	Covered	Total	%
statement	19	20	95.0
branch	2	4	50.0
condition			n/a
subroutine	7	8	87.5
pod	1	3	33.3
total	29	35	82.8

package Crypt::Random::Source::Weak::openssl; # git description: v0.02-6-g14c3ddf
# ABSTRACT: Get random bytes from the OpenSSL command line utility

use Moo;

use File::Which qw(which);

use namespace::clean;

our $VERSION = '0.03';

sub available {
	which("openssl");
}

extends qw(
	Crypt::Random::Source::Weak
	Crypt::Random::Source::Base::Proc
);

has openssl => (
	is => "rw",
	default => sub { which("openssl") },
	trigger => sub { shift->clear_command },
);

has default_chunk_size => (
	is => "rw",
	default => 1 << 16,
	trigger => sub { shift->clear_command },
);

has 'command' => (
	isa => sub { die "$_[0] must be an arrayref" unless ref $_[0] eq 'ARRAY' },
	is => 'lazy',
	clearer => "clear_command",
);

sub _build_command {
	my $self = shift;
	return [$self->openssl, "rand", $self->default_chunk_size];
}

sub BUILD {
	my $self = shift;
	$self->set_default_command;
}

sub set_default_command {
	my $self = shift;

	$self->default_chunk_size(1 << 16) # about 1.5x the overhead of simply spawning openssl rand 0 on my computer
		unless $self->default_chunk_size;

	$self->command([qw(openssl rand), $self->default_chunk_size])
		unless defined $self->command;
}

sub _read_too_short {
	my ( $self, $buf, $got, $req ) = @_;

	$self->close; # will cause openssl to be respawned

	return $buf . $self->get( $req - $got );
}

__PACKAGE__

__END__