File Coverage

blib/lib/Crypt/Passphrase/Argon2.pm

Criterion	Covered	Total	%
statement	32	33	96.9
branch	2	4	50.0
condition	12	16	75.0
subroutine	10	11	90.9
pod	5	5	100.0
total	61	69	88.4

package Crypt::Passphrase::Argon2;
$Crypt::Passphrase::Argon2::VERSION = '0.007';
use strict;
use warnings;

use Crypt::Passphrase 0.010 -encoder;

use Carp 'croak';
use Crypt::Argon2 0.017 qw/argon2_pass argon2_needs_rehash argon2_verify argon2_types/;

my %settings_for = (
	interactive => {
		time_cost   => 2,
		memory_cost => '64M',
	},
	moderate => {
		time_cost   => 3,
		memory_cost => '256M',
	},
	sensitive => {
		time_cost   => 4,
		memory_cost => '1G',
	}
);

my %valid_types = map { ($_ => 1) } argon2_types;

sub _settings_for {
	my %args = @_;
	my $subtype     =  $args{subtype}     // 'argon2id';
	croak "Unknown subtype $subtype" unless $valid_types{$subtype};
	my $profile     =  $args{profile}     // 'moderate';
	croak "Unknown profile $profile" unless $settings_for{$profile};
	return {
		memory_cost => $args{memory_cost} // $settings_for{$profile}{memory_cost},
		time_cost   => $args{time_cost}   // $settings_for{$profile}{time_cost},
		parallelism => $args{parallelism} //  1,
		output_size => $args{output_size} // 16,
		salt_size   => $args{salt_size}   // 16,
		subtype     => $subtype,
	};
}

sub new {
	my ($class, %args) = @_;
	return bless _settings_for(%args), $class;
}

sub hash_password {
	my ($self, $password) = @_;
	my $salt = $self->random_bytes($self->{salt_size});
	return argon2_pass($self->{subtype}, $password, $salt, @{$self}{qw/time_cost memory_cost parallelism output_size/});
}

sub needs_rehash {
	my ($self, $hash) = @_;
	return argon2_needs_rehash($hash, @{$self}{qw/subtype time_cost memory_cost parallelism output_size salt_size/});
}

sub crypt_subtypes {
	return argon2_types;
}

sub verify_password {
	my ($class, $password, $hash) = @_;
	return argon2_verify($hash, $password);
}

#ABSTRACT: An Argon2 encoder for Crypt::Passphrase

__END__