File Coverage

blib/lib/Crypt/EC_DSA.pm

Criterion	Covered	Total	%
statement	64	65	98.4
branch	6	10	60.0
condition	9	19	47.3
subroutine	14	14	100.0
pod	4	4	100.0
total	97	112	86.6

# -*-cperl-*-
#
# Crypt::EC_DSA - Elliptic Curve Digital Signature Algorithm (ECDSA)
# Copyright (c) 2017 Ashish Gulhati
#
# $Id: lib/Crypt/EC_DSA.pm v1.008 Thu Jun  8 22:19:29 PDT 2017 $

package Crypt::EC_DSA;

use warnings;
use strict;
use Bytes::Random::Secure;
use Math::EllipticCurve::Prime;
use Digest::SHA qw(sha256_hex);
use vars qw( $VERSION $AUTOLOAD );

our ( $VERSION ) = '$Revision: 1.008 $' =~ /\s+([\d\.]+)/;

sub new {
  my ($class, %arg) = @_;
  bless { debug => $arg{Debug} || 0,
	  curve => Math::EllipticCurve::Prime->from_name($arg{Curve} || 'secp256k1')
	}, $class;
}

sub keygen {
  my $self = shift;
  my $n = $self->curve->n; my $nlen = length($n->as_bin)-2; my $d = 0;
  my $random = Bytes::Random::Secure->new( Bits => 128 );
  $d = Math::BigInt->from_bin($random->string_from('01',$nlen)) until ($d > 1 and $d < $n);
  my $Q = $self->curve->g->multiply($d);
  $self->_diag("keygen(): d: $d, Q: x:" . $Q->x . ', y:' . $Q->y . "\n");
  return ($Q, $d);
}

sub sign {
  my ($self, %arg) = @_;
  my $n = $self->curve->n; my $nlen = length($n->as_bin);
  my $random = Bytes::Random::Secure->new( Bits => 128 );
  my ($k, $r, $s) = (0);
  until ($s) {
    until ($r) {
      $k = Math::BigInt->from_bin($random->string_from('01',$nlen-2)) until $k > 1 and $k < $n;
      $r = $self->curve->g->multiply($k)->x->bmod($n);
    }
    my $z = Math::BigInt->new(substr(Math::BigInt->from_hex(sha256_hex($arg{Message}))->as_bin,0,$nlen));
    $s = (($z + $arg{Key} * $r) * $k->bmodinv($n))->bmod($n);
  }
  $self->_diag("sign(): r: $r, s: $s\n");
  return ( bless { s => $s,
		   r => $r
		 }, 'Crypt::EC_DSA::Signature' );
}

sub verify {
  my ($self, %arg) = @_;
  my $n = $self->curve->n;
  my ($r, $s) = ($arg{Signature}->r, $arg{Signature}->s);
  $self->_diag("s: $s\nr: $r\n");
  return unless $r > 0 and $r < $n and $s > 0 and $s < $n;
  my $z = Math::BigInt->new(substr(Math::BigInt->from_hex(sha256_hex($arg{Message}))->as_bin,0,length($n->as_bin)));
  my $w = $s->copy->bmodinv($n);
  my $u1 = ($w * $z)->bmod($n); my $u2 = ($w * $r)->bmod($n);
  my $x1 = $self->curve->g->multiply($u1)->add($arg{Key}->multiply($u2))->x->bmod($n);
  $self->_diag("verify(): x1: $x1\nr: $r\n");
  $x1 == $r;
}

sub AUTOLOAD {
  my $self = shift; (my $auto = $AUTOLOAD) =~ s/.*:://;
  return if $auto eq 'DESTROY';
  if ($auto =~ /^(curve|debug)$/x) {
    $self->{$auto} = shift if (defined $_[0]);
    return $self->{$auto};
  }
  else {
    die "Could not AUTOLOAD method $auto.";
  }
}

sub _diag {
  my $self = shift;
  print STDERR @_ if $self->debug;
}

1; # End of Crypt::EC_DSA

package Crypt::EC_DSA::Signature;

sub r { shift->{r}; }

sub s { shift->{s}; }

1; # End of Crypt::EC_DSA::Signature;

__END__