File Coverage

blib/lib/Crypt/ECDH_ES.pm

Criterion	Covered	Total	%
statement	47	56	83.9
branch	3	12	25.0
condition			n/a
subroutine	9	10	90.0
pod	3	3	100.0
total	62	81	76.5

package Crypt::ECDH_ES;
$Crypt::ECDH_ES::VERSION = '0.002';
use strict;
use warnings;

use Carp;
use Crypt::Curve25519;
use Crypt::Rijndael;
use Digest::SHA qw/sha256 hmac_sha256/;

use Exporter 5.57 'import';
our @EXPORT_OK = qw/ecdhes_encrypt ecdhes_decrypt ecdhes_generate_key/;
our %EXPORT_TAGS = (all => \@EXPORT_OK);

my $csprng = ($^O eq 'MSWin32') ?
do {
	require Win32::API;
	my $genrand = Win32::API->new('advapi32', 'INT SystemFunction036(PVOID RandomBuffer, ULONG RandomBufferLength)') or croak "Could not import SystemFunction036: $^E";
	sub {
		my $count = shift;
		$genrand->Call(my $buffer, $count) or croak "Could not read from csprng: $^E";
		return $buffer;
	}
} :
do {
	open my $urandom, '<:raw', '/dev/urandom' or croak 'Couldn\'t open /dev/urandom';
	sub {
		my $count = shift;
		read $urandom, my $buffer, $count or croak "Couldn't read from csprng: $!";
		return $buffer;
	};
};

my $format = 'C/a C/a n/a N/a';

sub ecdhes_encrypt {
	my ($public_key, $data) = @_;

	my $private = curve25519_secret_key($csprng->(32));
	my $public  = curve25519_public_key($private);
	my $shared  = curve25519_shared_secret($private, $public_key);

	my ($encrypt_key, $sign_key) = unpack 'A16 A16', sha256($shared);
	my $iv     = substr sha256($public), 0, 16;
	my $cipher = Crypt::Rijndael->new($encrypt_key, Crypt::Rijndael::MODE_CBC);
	$cipher->set_iv($iv);

	my $pad_length = 16 - length($data) % 16;
	my $padding = chr($pad_length) x $pad_length;

	my $ciphertext = $cipher->encrypt($data . $padding);
	my $mac = hmac_sha256($iv . $ciphertext, $sign_key);
	return pack $format, '', $public, $mac, $ciphertext;
}

sub ecdhes_decrypt {
	my ($private_key, $packed_data) = @_;

	my ($options, $public, $mac, $ciphertext) = unpack $format, $packed_data;
	croak 'Unknown options' if $options ne '';

	my $shared = curve25519_shared_secret($private_key, $public);
	my ($encrypt_key, $sign_key) = unpack 'A16 A16', sha256($shared);
	my $iv     = substr sha256($public), 0, 16;
	croak 'MAC is incorrect' if hmac_sha256($iv . $ciphertext, $sign_key) ne $mac;
	my $cipher = Crypt::Rijndael->new($encrypt_key, Crypt::Rijndael::MODE_CBC);
	$cipher->set_iv($iv);

	my $plaintext = $cipher->decrypt($ciphertext);
	my $pad_length = ord substr $plaintext, -1;
	substr($plaintext, -$pad_length, $pad_length, '') eq chr($pad_length) x $pad_length or croak 'Incorrectly padded';
	return $plaintext;
}

sub ecdhes_generate_key {
	my $buf;
	if ($^O eq 'MSWin32') {
		$buf = $csprng->(32);
	}
	else {
		open my $fh, '<:raw', '/dev/random' or croak "Couldn't open /dev/random: $!";
		read $fh, $buf, 32 or croak "Can't read from /dev/random: $!";
		close $fh;
	}
	my $secret = curve25519_secret_key($buf);
	my $public = curve25519_public_key($secret);
	return ($public, $secret);
}

1;

#ABSTRACT: A fast and small hybrid crypto system

__END__