File Coverage

blib/lib/Crypt/Cipher/Vigenere.pm

Criterion	Covered	Total	%
statement	53	53	100.0
branch	6	6	100.0
condition			n/a
subroutine	10	10	100.0
pod	4	4	100.0
total	73	73	100.0

package Crypt::Cipher::Vigenere;

our $VERSION = '0.03';

use v5.20;
use strict;
use warnings;
use experimental 'signatures';

sub new ($class, $key) {
  bless( { key => $key, pos => 0 }, $class )
}

# return the current key character and advance the position
sub _next_key_letter ($self)
{
  my $c = substr($self->{key}, $self->{pos}, 1);
  $self->{pos}++;
  $self->{pos} = 0 unless $self->{pos} < length($self->{key});
  return $c;
}

# enciphering/deciphering function; the only difference is the direction of the
# shifts
sub _cipher ($self, $plaintext, $direction)
{
  my $ciphertext = '';

  # split into individual characters
  my @pt = split(//, $plaintext);

  # process plaintext characters
  foreach my $letter (@pt) {

    # we only operate on the 26 letters of the English alphabet, everything else
    # is passed through unchanged
    unless($letter =~ /[A-Z]/i) {
      $ciphertext .= $letter;
      next;
    }

    # get number of shifts
    my $shift = ord(uc $self->_next_key_letter) - ord('A');

    # shift the plaintext letter
    my $cipherletter .= chr(
      (
        (
          (
            ord(uc $letter) - ord('A')
          ) + $direction * $shift
        ) % 26
      ) + ord('A')
    );

    # preserve case
    $cipherletter = lc $cipherletter if $letter =~ /[a-z]/;

    # finish this iteration
    $ciphertext .= $cipherletter;
  }

  return $ciphertext;
}

# encode/decode mapped to the internal _cipher() function
sub encode ($self, $plaintext) { $self->_cipher($plaintext, 1) };
sub decode ($self, $ciphertext) { $self->_cipher($ciphertext, -1) };

# reset key position
sub reset ($self) { $self->{pos} = 0 }

1;

__END__