File Coverage

blib/lib/Cookieville/Read.pm

Criterion	Covered	Total	%
statement	45	46	97.8
branch	16	16	100.0
condition	2	2	100.0
subroutine	9	10	90.0
pod	1	1	100.0
total	73	75	97.3

package Cookieville::Read;

=head1 NAME

Cookieville::Read - Controller for getting data from the schema

=cut

use Mojo::Base 'Mojolicious::Controller';
use Mojo::JSON 'decode_json';

=head1 METHODS

=head2 search

Get data from a given source.

=cut

sub search {
  my $self = shift;
  my $rs   = eval { $self->db->resultset($self->stash('source')) };
  my $q    = decode_json($self->param('q') || 'null');
  my %extra;

  unless ($rs) {
    return $self->respond_to(
      csv => sub { shift->render(text => 'No source by that name.', status => 404); },
      txt => sub { shift->render(text => 'No source by that name.', status => 404); },
      any => sub { shift->render(json => {message => 'No source by that name.'}, status => 404); },
    );
  }
  unless (ref $q eq 'HASH') {
    return $self->respond_to(
      csv => sub { shift->render(text => 'Invalid (q) query param.', status => 400); },
      any => sub { shift->render(json => {message => 'Invalid (q) query param.'}, status => 400); },
    );
  }

  $extra{order_by} = decode_json $self->param('order_by') if $self->param('order_by');
  $extra{page}     = $self->param('page')                 if $self->param('page');
  $extra{rows}     = $self->param('limit')                if $self->param('limit');
  $extra{columns}  = decode_json $self->param('columns')  if $self->param('columns');

  $self->stash(extra => \%extra, rs => $rs->search_rs($q, \%extra));
  $self->respond_to(csv => \&_search_as_csv, txt => \&_search_as_csv, any => \&_search_as_json,);
}

sub _search_as_csv {
  my $self = shift;
  my $rs   = $self->stash('rs');
  my @columns;
  my @csv;

  if (my $columns = $self->stash('extra')->{columns}) {
    @columns = @$columns;
  }
  else {
    @columns = $rs->result_source->columns;
  }

  push @csv, join ',', @columns;

  while (my $row = $rs->next) {
    push @csv, join ',', map {
      my $v = $row->get_column($_);
      $v =~ s!"!""!g;
      $v =~ /[\s,]/ ? qq("$v") : $v;
    } @columns;
  }

  $self->render(text => join '', map {"$_\n"} @csv);
}

sub _search_as_json {
  my $self = shift;
  my $rs   = $self->stash('rs');
  my @data;

  while (my $row = $rs->next) {
    push @data, {$row->get_columns};
  }

  $self->render(json => {data => \@data});
}

=head1 AUTHOR

Jan Henning Thorsen - C

=cut

1;