File Coverage

blib/lib/Convert/Color/LCh.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	6	6	100.0
condition			n/a
subroutine	15	15	100.0
pod	6	9	66.6
total	68	71	95.7

package Convert::Color::LCh;

use 5.008009;
use strict;
use warnings;
use parent qw/Convert::Color/;

our $VERSION = '1.000001';

use Convert::Color::LUV;
use Math::Trig ':pi';

__PACKAGE__->register_color_space('lch');

sub new {
	my ($class, $l, $c, $h) = @_;
	($l, $c, $h) = split /,/s, $l unless defined $c;
	bless [$l, $c, $h], $class
}

sub L { shift->[0] }
sub C { shift->[1] }
sub h { shift->[2] }

sub lch { @{$_[0]} }

sub convert_to_luv {
	my ($self) = @_;
	my ($l, $c, $h) = @$self;
	my $hrad = $h / 180 * pi;
	my $u = $c * cos $hrad;
	my $v = $c * sin $hrad;
	Convert::Color::LUV->new($l, $u, $v)
}

sub new_from_luv {
	my ($class, $luv) = @_;
	my ($l, $u, $v) = @$luv;
	my $c = sqrt $u * $u + $v * $v;
	return $class->new($l, $c, 0) if $c < 0.00000001;
	my $hrad = atan2 $v, $u;
	my $h = $hrad * 180 / pi;
	$h += 360 if $h < 0;
	$class->new($l, $c, $h)
}

sub rgb { shift->convert_to_luv->rgb }
sub new_rgb { shift->new_from_luv(Convert::Color::LUV->new_rgb(@_)) }

1;
__END__