File Coverage

blib/lib/Contextual/Diag.pm

Criterion	Covered	Total	%
statement	50	50	100.0
branch	16	16	100.0
condition	4	4	100.0
subroutine	18	18	100.0
pod	1	1	100.0
total	89	89	100.0

package Contextual::Diag;
use 5.010;
use strict;
use warnings;

our $VERSION = "0.04";

use Exporter;
our @ISA = qw/Exporter/;
our @EXPORT = qw/contextual_diag/;

use Carp ();
use Contextual::Diag::Value;

sub contextual_diag {

    if (wantarray) {
        _diag('wanted LIST context');
        return @_;
    }
    elsif(!defined wantarray) {
        _diag('wanted VOID context');
        return;
    }
    else {
        _diag('wanted SCALAR context');

        return Contextual::Diag::Value->new($_[0],
            BOOL      => sub { _diag('evaluated as BOOL in SCALAR context');  return $_[0] },
            NUM       => sub { _diag('evaluated as NUM in SCALAR context');   return $_[0] || 0   },
            STR       => sub { _diag('evaluated as STR in SCALAR context');   return $_[0] || ""  },
            SCALARREF => sub { _diag('scalar ref is evaluated as SCALARREF'); return defined $_[0] ? $_[0] : \"" },
            ARRAYREF  => sub { _diag('scalar ref is evaluated as ARRAYREF');  return defined $_[0] ? $_[0] : [] },
            HASHREF   => sub { _diag('scalar ref is evaluated as HASHREF');   return defined $_[0] ? $_[0] : {} },
            CODEREF   => sub { _diag('scalar ref is evaluated as CODEREF');   return defined $_[0] ? $_[0] : sub { } },
            GLOBREF   => sub { _diag('scalar ref is evaluated as GLOBREF');   return defined $_[0] ? $_[0] : do { no strict qw/refs/; my $package = __PACKAGE__; \*{$package} } },
            OBJREF    => sub { _diag('scalar ref is evaluated as OBJREF');    return defined $_[0] ? $_[0] : bless {}, __PACKAGE__ },
        );
    }
}

sub _diag {
    local $Carp::CarpLevel = 2;
    goto &Carp::carp;
}

1;
__END__