File Coverage

blib/lib/Contextual/Diag.pm

Criterion	Covered	Total	%
statement	50	50	100.0
branch	18	18	100.0
condition	3	3	100.0
subroutine	20	20	100.0
pod	1	1	100.0
total	92	92	100.0

package Contextual::Diag;
use 5.010;
use strict;
use warnings;

our $VERSION = "0.02";

use Exporter;
our @ISA = qw/Exporter/;
our @EXPORT = qw/contextual_diag/;

use Contextual::Return;
use Carp ();

sub contextual_diag {

    # XXX: SCALAR block is lazy.
    # https://metacpan.org/pod/Contextual%3A%3AReturn#Lazy-contextual-return-values
    if (defined wantarray && !wantarray) {
        _diag('wanted SCALAR context');
    }

    return
        VOID     { _diag('wanted VOID context'); @_ }
        LIST     { _diag('wanted LIST context'); @_ }

        # Scalar Value
        BOOL     { _diag('evaluated as BOOL in SCALAR context'); $_[0] }
        NUM      { _diag('evaluated as NUM in SCALAR context');  $_[0] || 0   }
        STR      { _diag('evaluated as STR in SCALAR context');  $_[0] || ""  }

        # Scalar Reference
        SCALARREF { _diag('scalar ref is evaluated as SCALARREF'); defined $_[0] ? $_[0] : \"" }
        ARRAYREF  { _diag('scalar ref is evaluated as ARRAYREF');  defined $_[0] ? $_[0] : [] }
        HASHREF   { _diag('scalar ref is evaluated as HASHREF');   defined $_[0] ? $_[0] : {} }
        CODEREF   { _diag('scalar ref is evaluated as CODEREF');   defined $_[0] ? $_[0] : sub { } }
        GLOBREF   { _diag('scalar ref is evaluated as GLOBREF');   defined $_[0] ? $_[0] : do { no strict qw/refs/; my $package = __PACKAGE__; \*{$package} } }
        OBJREF    { _diag('scalar ref is evaluated as OBJREF');    defined $_[0] ? $_[0] : bless {}, __PACKAGE__ }
    ;
}

sub _diag {
    local $Carp::CarpLevel = 2;
    goto &Carp::carp;
}

1;
__END__